blob: ccd573843f60e0a63f05676f1a40b15069bfbb23 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Torsten Keßler <t dot kessler at posteo dot de>
# Contributor: Markus Näther <naetherm@informatik.uni-freiburg.de>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
pkgname=hipsparse
pkgver=5.3.0
pkgrel=1
pkgdesc='rocSPARSE marshalling library.'
arch=('x86_64')
url='https://hipsparse.readthedocs.io/en/latest/'
license=('MIT')
depends=('hip' 'rocsparse')
makedepends=('cmake' 'git' 'gcc-fortran')
_git='https://github.com/ROCmSoftwarePlatform/hipSPARSE'
source=("$pkgname-$pkgver.tar.gz::$_git/archive/rocm-$pkgver.tar.gz")
sha256sums=('691b32b916952ed9af008aa29f60cc190322b73cfc098bb2eda3ff68c89c7b35')
_dirname="$(basename "$_git")-$(basename "${source[0]}" ".tar.gz")"
build() {
# -fcf-protection is not supported by HIP, see
# https://docs.amd.com/bundle/ROCm-Compiler-Reference-Guide-v5.3/page/Appendix_A.html
CXXFLAGS="${CXXFLAGS} -fcf-protection=none" \
HIP_PATH=/opt/rocm \
cmake \
-Wno-dev \
-B build \
-S "$_dirname" \
-DCMAKE_CXX_COMPILER=/opt/rocm/bin/hipcc \
-DCMAKE_INSTALL_PREFIX=/opt/rocm \
-DBUILD_CLIENTS_SAMPLES=OFF \
-DBUILD_CLIENTS_TESTS=OFF
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
echo "/opt/rocm/$pkgname/lib" > "$pkgname.conf"
install -Dm644 "$pkgname.conf" "$pkgdir/etc/ld.so.conf.d/$pkgname.conf"
install -Dm644 "$srcdir/hipSPARSE-rocm-$pkgver/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|