blob: c7b6678a895e5b021b52e4cf493daa378dd87325 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=homebridge
pkgver=1.4.1
pkgrel=1
pkgdesc='HomeKit support for the impatient'
arch=('any')
url='https://github.com/homebridge/homebridge'
license=('Apache')
depends=('nodejs')
makedepends=('npm')
optdepends=('homebridge-config-ui-x: for web-based management tool')
options=('!emptydirs' '!strip')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('68eb0aa8030452b8c54614f651956ac9a8cc2e2cc95b083b1d68401578f83dea88e094833f1c3e786141f2a3cf0e69d7339a1c3fe2eb9068e2dab3e6bbddd903')
b2sums=('2903cac86a7b07765c52d8d779381fcbb5b795696a191eaf11ee93a6f6d683f29cb54f236796f5b7bd8be24efa35138b9cc6cb3a444ec120bdb47f0403dcab63')
build() {
cd "$pkgname-$pkgver"
# NOTE: package is built this way because the dist/ directory is not
# included in the source, only in npm source due to a prepublish script
# which does not get installed correctly if the npm source is used.
export NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
# install dependencies
npm install "${NPM_FLAGS[@]}"
# generate dist dir
npm run build "${NPM_FLAGS[@]}"
# generate tarball
npm pack "${NPM_FLAGS[@]}"
}
package() {
cd "$pkgname-$pkgver"
npm install \
--global \
--prefix "$pkgdir/usr" \
"${NPM_FLAGS[@]}" \
"$pkgname-$pkgver.tgz"
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "$pkgdir"
unset NPM_FLAGS
}
|