blob: a6d4d1649c061d71aa252c840a34eefe77d630b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=homebridge
pkgver=1.5.0
pkgrel=1
pkgdesc='HomeKit support for the impatient'
arch=('any')
url='https://github.com/homebridge/homebridge'
license=('Apache')
depends=('nodejs')
makedepends=('npm')
optdepends=('homebridge-config-ui-x: for web-based management tool')
options=('!emptydirs' '!strip')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('7aa6d67f07e0135d9eed58d5a769b8204ee694de0658cd01d0c663e10dbd95669f09acbb06704bdc1d7bdd0c1882bff8ec2ce5ec4458b5a9e5c62bf61fcde427')
b2sums=('7dfd711b302e090f610b800b00bff6257c67d706332585d97b9540032cfa54f807d343a690d609308a9c703a304ebc336964b1ace29f1a3fea8c69db3b9e853b')
build() {
cd "$pkgname-$pkgver"
# NOTE: package is built this way because the dist/ directory is not
# included in the source, only in npm source due to a prepublish script
# which does not get installed correctly if the npm source is used.
export NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
# install dependencies
npm install "${NPM_FLAGS[@]}"
# generate dist dir
npm run build "${NPM_FLAGS[@]}"
# generate tarball
npm pack "${NPM_FLAGS[@]}"
}
package() {
cd "$pkgname-$pkgver"
npm install \
--global \
--prefix "$pkgdir/usr" \
"${NPM_FLAGS[@]}" \
"$pkgname-$pkgver.tgz"
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "$pkgdir"
unset NPM_FLAGS
}
|