blob: 692591a82f6c1d9e33f5a95059e6bda97837c5da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Marco Rubin <marco.rubin@protonmail.com>
# Contributor: Florian Lindner <florian.lindner@xgm.de>
pkgname=hotspot
pkgver=20240412
_commit=d274358cefa0aa989d760091dc30a2f8a8030560
pkgrel=1
pkgdesc="The Linux perf GUI for performance analysis"
arch=('x86_64')
url="https://github.com/KDAB/hotspot"
license=('GPL-2.0-only')
depends=(
'elfutils'
'kconfig'
'kconfigwidgets'
'kcoreaddons'
'kddockwidgets-qt6'
'kgraphviewer'
'ki18n'
'kio'
'kitemmodels'
'kitemviews'
'kparts'
'libelf'
'perf'
# 'qcustomplot' # currently it doesn't build
'qt6-base'
'rustc-demangle>=0.1.18-2'
'solid'
'syntax-highlighting'
'threadweaver'
)
makedepends=('cmake>=3.16.0' 'desktop-file-utils' 'extra-cmake-modules' 'git')
source=("git+$url#commit=$_commit"
"git+https://github.com/KDAB/perfparser.git"
"git+https://github.com/koenpoppe/PrefixTickLabels")
b2sums=('55c9f16b657773e5eec8a0be8242de9b205298d22f2731df2209028ea74fbedc70e906b799595fc1a16e4676a993c7401b82b24bbd555c9af8249192a5dc6f24'
'SKIP'
'SKIP')
pkgver() {
cd $pkgname
git log -n1 --pretty='format:%cd' --date=format:'%Y%m%d' $_commit
}
prepare() {
cd $pkgname
git submodule init
git config submodule.3rdparty/perfparser.url "$srcdir/perfparser"
git config submodule.3rdparty/PrefixTickLabels.url "$srcdir/PrefixTickLabels"
git -c protocol.file.allow=always submodule update
}
build() {
cd $pkgname
cmake -DBUILD_TESTING=off -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DQT6_BUILD=on .
cmake --build .
}
package() {
cd $pkgname
DESTDIR="$pkgdir" cmake --install .
desktop-file-install com.kdab.hotspot.desktop --dir="$pkgdir/usr/share/applications/"
}
|