PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Marco Rubin <marco.rubin@protonmail.com>
# Contributor: Florian Lindner <florian.lindner@xgm.de>

pkgname=hotspot
pkgver=20240304
pkgrel=1
pkgdesc="The Linux perf GUI for performance analysis"
arch=('x86_64')
url="https://github.com/KDAB/hotspot"
license=('GPL-2.0-only')
depends=(
    'elfutils'
    'kconfig5'
    'kconfigwidgets5'
    'kcoreaddons5'
    'kddockwidgets'
    'ki18n5'
    'kio5'
    'kitemmodels5'
    'kitemviews5'
    'kparts5'
    'libelf'
    'perf'
    'qt5-base>=5.15.0'
    'rustc-demangle>=0.1.18-2'
    'solid5'
    'threadweaver5'
)
makedepends=('cmake>=3.16.0' 'desktop-file-utils' 'extra-cmake-modules' 'git')
source=("git+$url#commit=6f9f958c4ff68b3c94ccca0fa3c2d86c46c9185f")
b2sums=('SKIP')

prepare() {
    cd $pkgname
    git submodule update --init --recursive
}

build() {
    cd $pkgname
    cmake -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_TESTING=off .
    cmake --build .
}

package() {
    cd $pkgname
    DESTDIR="$pkgdir" cmake --install .
    desktop-file-install com.kdab.hotspot.desktop --dir="$pkgdir/usr/share/applications/"
}