blob: a8d4b6b8f9ec965cda3a530d3937ba7505312beb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: kastik <kostas21422112@gmail.com>
# Contributor: Guillaume ETHEVE <admin@guillaume-etheve.fr>
# Contributor: Caleb Fontenot <foley2431@gmail.com>
# Contributor: Angelo Verlain <hey@vixalien.com>
pkgname=howdy-beta-git
pkgver=2.6.1.r239.gc5b1766
pkgrel=2
pkgdesc="Windows Hello for Linux (Beta)"
arch=('x86_64')
url="https://github.com/boltgolt/howdy"
license=('MIT')
depends=(
'opencv'
'hdf5'
'python'
'python-pillow'
'python-dlib'
'python-face_recognition'
'python-face_recognition_models'
'python-click'
'python-numpy'
'python-opencv'
'libinih'
)
makedepends=(
'cmake'
'pkgfile'
'meson'
'git'
'libevdev'
'libinih'
'pam'
'gettext'
)
optdepends=(
'python-elevate: for GUI howdy-gtk'
)
conflicts=(
'howdy'
)
provides=(
'howdy'
)
backup=('etc/howdy/config.ini')
source=(
"git+https://github.com/boltgolt/howdy.git#branch=beta"
"https://github.com/davisking/dlib-models/raw/master/dlib_face_recognition_resnet_model_v1.dat.bz2"
"https://github.com/davisking/dlib-models/raw/master/mmod_human_face_detector.dat.bz2"
"https://github.com/davisking/dlib-models/raw/master/shape_predictor_5_face_landmarks.dat.bz2"
)
sha256sums=('SKIP'
'abb1f61041e434465855ce81c2bd546e830d28bcbed8d27ffbe5bb408b11553a'
'db9e9e40f092c118d5eb3e643935b216838170793559515541c56a2b50d9fc84'
'6e787bbebf5c9efdb793f6cd1f023230c4413306605f24f299f12869f95aa472'
)
pkgver() {
cd "$srcdir/howdy"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson $srcdir/howdy build -Dinstall_pam_config=true -Ddlib_data_dir="/etc/howdy/dlib-data"
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
install -dm755 "${pkgdir}/etc/howdy/dlib-data"
install -Dm644 "${srcdir}/dlib_face_recognition_resnet_model_v1.dat" "${pkgdir}/etc/howdy/dlib-data"
install -Dm644 "${srcdir}/mmod_human_face_detector.dat" "${pkgdir}/etc/howdy/dlib-data"
install -Dm644 "${srcdir}/shape_predictor_5_face_landmarks.dat" "${pkgdir}/etc/howdy/dlib-data"
}
|