PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Pierre Neidhardt <ambrevar@gmail.com>

_pkgname=hsync
pkgname=$_pkgname
pkgver=1.3
pkgrel=3
pkgdesc="A filesystem hierarchy synchronizer"
arch=("i686" "x86_64")
url="http://ambrevar.bitbucket.io/hsync/"
license=("MIT")
makedepends=("go")
source=("$pkgname-$pkgver.tar.bz2::https://bitbucket.org/ambrevar/$_pkgname/get/v$pkgver.tar.bz2")
sha1sums=("6c6c12b3364ebb0924cd2cc56844aa58bc3970c5")
_gourl="bitbucket.org/ambrevar/$_pkgname"

prepare() {
	## Move source extracted folder to its proper location in the GOPATH.
	cd "$srcdir"
	rm -rfv "src/$_gourl"
	mkdir -p "src/bitbucket.org/ambrevar"
	mv "ambrevar-$_pkgname-2c7344b758a9" "src/$_gourl"
}

build() {
	case "$CARCH" in
	x86_64) GOARCH=amd64 ;;
	i686) GOARCH=386 ;;
	esac

	GOPATH="$srcdir" go get -v -x -ldflags "-X main.version=$pkgver" "$_gourl"
}

check() {
	GOPATH="$srcdir" go test -v -x "$_gourl"
}

package() {
	cd "$srcdir"
	install -Dm755 "bin/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
	install -Dm644 "src/$_gourl/LICENSE" "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}