blob: fe78444466d6e511e7a647c78c2beefdc27e7521 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
_name=HTMLHint
pkgname=htmlhint
pkgver=0.15.1
pkgrel=1
pkgdesc='Static Code Analysis Tool for your HTML'
arch=('any')
url=https://htmlhint.com/
license=('MIT')
depends=('nodejs')
makedepends=('git' 'npm')
source=("git+https://github.com/htmlhint/HTMLHint.git#tag=v$pkgver")
b2sums=('SKIP')
build() {
cd $_name
npm ci
npm run build
}
check() {
cd $_name
npm test
}
package() {
cd $_name
npm prune --production
install -d "$pkgdir"/usr/bin
ln -s ../lib/node_modules/$pkgname/bin/$pkgname "$pkgdir"/usr/bin/$pkgname
install -Dt "$pkgdir"/usr/lib/node_modules/$pkgname/bin bin/$pkgname
cp -r dist node_modules package.json "$pkgdir"/usr/lib/node_modules/$pkgname
install -Dm644 -t "$pkgdir"/usr/share/doc/$pkgname \
{CHANGELOG,CONTRIBUTING,README}.md
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE.md
}
# vim:set ts=2 sw=2 et:
|