blob: a36081fdbe2acf56725b1d33dad7b55c84e3ecf9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Sean Greenslade <aur AT seangreenslade DOT com>
# Contributor: Lars Rustand <rustand dot lars at gmail dot com>
# Contributor: Boohbah <boohbah at gmail.com>
# Contributor: Eric Belanger <eric at archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
# Contributor: Wesley Merkel <ooesili at gmail.com>
# Contributor: sekret <sekret at posteo.se>
_pkgname=htop
pkgname=$_pkgname-solarized
_tag='a8637afe0398f0be0131f73563b55ef9315ca351' # git rev-parse ${pkgver}
pkgver=3.1.0
pkgrel=2
pkgdesc="Interactive process viewer with solarized patch"
arch=('i686' 'x86_64' 'armv7h')
url='https://htop.dev/'
license=('GPL')
depends=('libcap' 'libcap.so' 'libnl' 'ncurses' 'libncursesw.so')
makedepends=('git' 'lm_sensors')
optdepends=('lm_sensors: show cpu temperatures'
'lsof: show files opened by a process'
'strace: attach to a running process')
provides=('htop')
conflicts=('htop')
options=('!emptydirs')
validpgpkeys=('F7ABE8761E6FE68638E6283AFE0842EE36DD8C0C') # Nathan Scott <nathans@debian.org>
source=("git+https://github.com/htop-dev/htop.git#tag=${_tag}?signed"
'htop-solarized.patch')
sha256sums=('SKIP'
'a89800696603ad3ccdfc9a51345f6b24d7de651e1e8691dc16671e951b4cc3e5')
prepare() {
cd "${_pkgname}"
autoreconf -fi
# Solarized patch
patch -p1 -N -i "${srcdir}/htop-solarized.patch"
}
build() {
cd "${_pkgname}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-cgroup \
--enable-delayacct \
--enable-openvz \
--enable-unicode \
--enable-vserver
make
}
package() {
cd "${_pkgname}"
make DESTDIR="${pkgdir}" install
}
# vim:set ts=2 sw=2 et:
|