blob: abdf12eb306264e8dc14385f77329a4e6081edf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Christopher Vittal ("viralstitch") <chris@vittal.dev>
pkgname=htslib
pkgver=1.12
pkgrel=1
pkgdesc="library for high-throughput sequencing data formats"
arch=('i686' 'x86_64')
url="https://github.com/samtools/htslib"
license=('custom')
depends=('bzip2' 'curl' 'xz')
provides=('tabix')
replaces=('tabix')
conflicts=('tabix')
source=(https://github.com/samtools/htslib/releases/download/$pkgver/$pkgname-$pkgver.tar.bz2)
sha256sums=('2280141b46e953ba4ae01b98335a84f8e6ccbdb6d5cdbab7f70ee4f7e3b6f4ca')
build() {
cd $srcdir/$pkgname-$pkgver
./configure \
--prefix=/usr \
--enable-libcurl \
--enable-plugins \
--with-plugin-dir=/usr/lib/htslib/plugins
make
}
check() {
cd $srcdir/$pkgname-$pkgver
make check
}
package() {
cd $srcdir/$pkgname-$pkgver
make DESTDIR=$pkgdir install
install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
# htslib shared library comes installed as 0644
chmod +x $pkgdir/usr/lib/libhts.so.*.*
}
|