summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e710894994c7cccb673cfe7a62bb32703b37326c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=htslib-git
pkgver=1.10.2.r134.ge9447f86
pkgrel=2
pkgdesc="C library for high-throughput sequencing data formats"
arch=('i686' 'x86_64')
url="https://github.com/samtools/htslib"
license=('custom')
depends=('glibc' 'bzip2' 'curl' 'openssl' 'xz')
makedepends=('git')
provides=('htslib')
conflicts=('htslib')
options=('staticlibs')
source=("git+https://github.com/samtools/htslib.git")
sha256sums=('SKIP')


pkgver() {
  cd "htslib"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "htslib"

  autoreconf -fi
  ./configure \
    --prefix="/usr" \
    --enable-plugins \
    --with-plugin-dir="/usr/lib/htslib/plugins" \
    --enable-gcs \
    --enable-s3
  make
}

check() {
  cd "htslib"

  #make check
}

package() {
  cd "htslib"

  make DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/htslib"
}