PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: taotieren <admin@taotieren.com>

pkgname=huawei-modem-calculator-git
pkgver=r37.f007c01
pkgrel=2
pkgdesc="Huawei modem unlock code calculator with the USB serial interface"
arch=($CARCH)
url="https://github.com/bigbigmdm/Huawei_modem_calculator_v2"
license=('GPL-2.0-only')
groups=()
_qt=qt5
depends=(
    glibc
    libgcc
    libstdc++
    $_qt-base
    $_qt-serialport
    openssl
)
makedepends=(
    cmake
    git
    ninja
    $_qt-tools
    pkgconf
)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
replaces=()
backup=()
options=()
install=
source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')
noextract=()

pkgver() {
    cd "${srcdir}/${pkgname}"
    (
        set -o pipefail
        git describe --long --tag --abbrev=7 2>/dev/null | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g' ||
            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    )
}

prepare() {
    git -C "${srcdir}/${pkgname}" clean -dfx
}

build() {
    cmake -S "$srcdir/${pkgname}" \
        -DCMAKE_BUILD_TYPE=None \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -B build \
        -G Ninja \
        -Wno-dev

    ninja -C $srcdir/build
}

package() {
    DESTDIR="${pkgdir}" ninja -C ${srcdir}/build install
    install -Dm644 ${srcdir}/${pkgname}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
}