PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

# Maintainer: LIghtJUNction
pkgname=humen-mcp-bin
pkgver=0.1.20
pkgrel=1
pkgdesc='Human-in-the-loop MCP server'
arch=('x86_64')
url='https://github.com/LIghtJUNction/humen-mcp'
license=('MIT')
depends=('gcc-libs' 'openssl' 'sudo')
provides=('humen-mcp')
conflicts=('humen-mcp' 'humen-mcp-git')
backup=('etc/humen-mcp.env')
install=humen-mcp.install
source=("https://github.com/LIghtJUNction/humen-mcp/releases/download/v${pkgver}/humen-mcp-${pkgver}-x86_64-unknown-linux-gnu.tar.gz")
sha256sums=('26d559d96e0c016192699c32893edfa6bb1861db98ddfd1693f543d60bfe048e')

package() {
  cd "humen-mcp-${pkgver}-x86_64-unknown-linux-gnu"
  install -Dm755 humen-mcp "$pkgdir/usr/bin/humen-mcp"
  install -Dm644 packaging/systemd/humen-mcp.service "$pkgdir/usr/lib/systemd/system/humen-mcp.service"
  install -Dm644 packaging/systemd/humen-mcp-self-update.service "$pkgdir/usr/lib/systemd/system/humen-mcp-self-update.service"
  install -Dm755 packaging/scripts/humen-mcp-self-update "$pkgdir/usr/lib/humen-mcp/humen-mcp-self-update"
  install -Dm440 packaging/sudoers/humen-mcp-self-update "$pkgdir/etc/sudoers.d/humen-mcp-self-update"
  install -Dm644 packaging/sysusers/humen-mcp.conf "$pkgdir/usr/lib/sysusers.d/humen-mcp.conf"
  install -Dm644 packaging/tmpfiles/humen-mcp.conf "$pkgdir/usr/lib/tmpfiles.d/humen-mcp.conf"
  install -Dm640 env.example "$pkgdir/etc/humen-mcp.env"
  install -dm755 "$pkgdir/usr/share/humen-mcp/web"
  cp -a --no-preserve=ownership web/. "$pkgdir/usr/share/humen-mcp/web/"
}