blob: 4110831a5bab27d43b5dd40311052107207d89e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=hunspell-git
pkgver=1.7.2.r18.g527b67d
pkgrel=1
pkgdesc="The most popular spellchecking library"
arch=('i686' 'x86_64')
url="https://hunspell.github.io/"
license=('LGPL')
depends=('glibc' 'ncurses' 'readline')
makedepends=('git')
optdepends=('perl: for ispellaff2myspell')
provides=("hunspell=$pkgver")
conflicts=('hunspell')
options=('staticlibs')
source=("git+https://github.com/hunspell/hunspell.git")
sha256sums=('SKIP')
pkgver() {
cd "hunspell"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "hunspell"
autoreconf -fi
./configure \
--prefix="/usr" \
--with-readline \
--with-ui
make
}
check() {
cd "hunspell"
make check
}
package() {
cd "hunspell"
make DESTDIR="$pkgdir" install
# add generic hunspell.so for development and projects not using pkgconfig flags - FS#30592
cd "$pkgdir/usr/lib"
ln -s libhunspell-?.?.so "libhunspell.so"
}
|