summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9de01e6f921c04b32dc96294c3a98cb3830e66c6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: OctopusET

pkgname=hunspell-ko
pkgver=0.7.92
pkgrel=3
pkgdesc="Korean dictionary for hunspell"
arch=('any')
url='https://github.com/spellcheck-ko/hunspell-dict-ko'
license=('GPL3')
depends=('hunspell>=1.3.1')
makedepends=('python-yaml')

source=("${pkgname}-${pkgver}.tar.gz::https://github.com/spellcheck-ko/hunspell-dict-ko/archive/${pkgver}.tar.gz")
sha1sums=('41085dac1529224d96bfef13fa7fc836aeee5bda')
build() {
	cd "$srcdir/hunspell-dict-ko-$pkgver"
	make VERSION=$pkgver DESTDIR="$pkgdir" PREFIX=/usr
}

package() {
	cd "$srcdir/hunspell-dict-ko-$pkgver" 
	install -dm755 "${pkgdir}/usr/share/hunspell"
	install -m644 ko.dic "${pkgdir}"/usr/share/hunspell
	install -m644 ko.aff "${pkgdir}"/usr/share/hunspell
	pushd "$pkgdir"/usr/share/hunspell
	for file in ko.*; do
		ln -s ${file} ko_KR."${file#*.}"
	done
	popd

# symlinks
	install -dm755 "${pkgdir}"/usr/share/myspell/dicts
	pushd "$pkgdir"/usr/share/myspell/dicts
	for file in "${pkgdir}"/usr/share/hunspell/*; do
		ln -sv /usr/share/hunspell/$(basename $file) .
	done
	popd

# licenses
	install -Dm644 LICENSE.md $pkgdir/usr/share/licenses/$pkgname/LICENSE
}