blob: 4487888c7730edf7493e39be91aabbb31b989fec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Thorben Günther <echo YWRtaW5AeGVucm94Lm5ldAo= | base64 -d>
pkgname=hut-git
_pkgname=hut
pkgver=r244.ed21e0c
pkgrel=1
pkgdesc='A CLI tool for sr.ht (sourcehut)'
arch=('x86_64' 'aarch64')
url='https://sr.ht/~emersion/hut'
license=('AGPL3')
makedepends=('git' 'go' 'scdoc')
provides=('hut')
conflicts=('hut')
source=("$_pkgname::git+https://git.sr.ht/~emersion/${_pkgname}")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
check() {
cd "$srcdir/$_pkgname"
go test ./...
}
build() {
cd "$srcdir/$_pkgname"
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
make -e
}
package() {
cd "$srcdir/$_pkgname"
make PREFIX=/usr DESTDIR=$pkgdir install
}
|