PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: prime-run <prime-run@githiub.com>

pkgname=hyde-ipc-git
_pkgname=hyde-ipc

pkgver=0.1.2
pkgrel=1

pkgdesc="Control Hyprland, query its state, listen for events, and create automated reactions to events."

arch=("x86_64"  "aarch64")
license=('MIT')
url="https://github.com/HyDE-Project/hyde-ipc"

depends=(hyprland)
makedepends=("cargo" "git")

source=("git+$url.git")
sha256sums=(SKIP)


pkgver() {
  cd "$_pkgname"
  git describe --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {

    export RUSTUP_TOOLCHAIN=stable
    cd "$_pkgname"
    cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}


build() {
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cd "$_pkgname"
    cargo build --frozen --release
}

package() {
    cd "$_pkgname"
    install -Dm755 "target/release/hyde-ipc" "$pkgdir/usr/bin/hyde-ipc"
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}