blob: 43d4f8ab5a427e1d5d08e06befdf1ce62ded6b37 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=hydrapaper
pkgver=3.2.0+14+g760e06f
pkgrel=1
pkgdesc="A Gtk utility to set different backgrounds for each monitor on GNOME"
arch=('any')
url="https://hydrapaper.gabmus.org"
license=('GPL3')
depends=('gtk4' 'libadwaita' 'dbus-python' 'python-gobject' 'python-pillow')
makedepends=('blueprint-compiler' 'git' 'gobject-introspection' 'meson' 'pandoc')
checkdepends=('appstream')
_commit=760e06f7cd2910fe70cdd31a736e016a21549c91
source=("git+https://gitlab.gnome.org/GabMus/HydraPaper.git#commit=$_commit")
#source=("https://gitlab.gnome.org/GabMus/HydraPaper/-/archive/$pkgver/HydraPaper-$pkgver.tar.gz")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/HydraPaper"
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "$srcdir/HydraPaper"
sed -i 's/1.0.0.alpha.3/1.0.0/g' meson.build
}
build() {
arch-meson HydraPaper build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|