blob: cf42d8c17d367fe87f6e5e6f296636d64ebd2f06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Score_Under <seejay 11@gmail com>
options=(!strip) # Don't strip libs because there aren't any
DOC_DIRS=(opt/hydrus/help)
pkgbase=hydrus
pkgname=(hydrus)
pkgver=433
pkgrel=3
pkgdesc="Danbooru-like image tagging and searching system for the desktop"
arch=(any)
license=(WTFPL)
install=hydrus.install
conflicts=(hydrus-docs hydrus-sources)
url=http://hydrusnetwork.github.io/hydrus/
depends=(python opencv glew vtk python-beautifulsoup4 python-yaml
'python-lz4>=0.10.1' python-numpy python-twisted python-pillow
python-pysocks python-psutil python-send2trash python-html5lib
python-requests hdf5 python-qtpy emoji-font python-mpv
qt5-python-bindings)
makedepends=(git)
optdepends=('ffmpeg: show duration and other information on video thumbnails'
'miniupnpc: automatic port forwarding'
'desktop-file-utils: to add Hydrus to your desktop environment menus'
'python-cloudscraper: bypass cloudflare "checking your browser" challenges'
'python-pyqt5-chart: display bandwidth usage charts'
'python-pyopenssl: to generate certificates for accessing client API and server via HTTPS')
source=("${pkgbase}::git+https://github.com/hydrusnetwork/${pkgbase}.git#commit=4cefd895b55131d2a9c1433d71dd98815e654241"
paths-in-opt.patch
hydrus-client
hydrus-server
hydrus.desktop)
sha256sums=('SKIP'
'3cf240b1f3fc405b4e86030e45d54984bd425e37c6f48205a9419c2c0a94bcd2'
'd2cb826ce0dd1892ab95fc3b14dbe6bd312210f653d0aea31938eeb7e361fdc5'
'463841cc16059b516cc327cfbc30d3383e2236b085ba2d503e82f5be39444806'
'9b8c2603a8040ae80152ff9a718ad3e8803fdc3029a939e3c0e932ea35ded923')
prepare() {
cd "$pkgbase"
git apply < ../paths-in-opt.patch
# Remove unit tests
rm -f "hydrus/Test"*.py
rm -rf "static/testing"
}
build() {
cd "$pkgbase"
msg 'Compiling .py files...'
python -OO -m compileall -fq .
}
package_hydrus() {
cd "$pkgbase"
# Create /opt/hydrus and copy hydrus files to there
install -m755 -d "${pkgdir}/opt/hydrus"
cp -r help hydrus static client.pyw server.py "${pkgdir}/opt/hydrus/"
# Create and populate /opt/hydrus/bin
install -d -m755 "${pkgdir}/opt/hydrus/bin"
ln -s /usr/bin/upnpc "${pkgdir}/opt/hydrus/bin/upnpc_linux"
ln -s /usr/bin/ffmpeg "${pkgdir}/opt/hydrus/bin/ffmpeg"
# Install hydrus-client and hydrus-server executables
install -d -m755 "${pkgdir}/usr/bin"
install -m755 ../hydrus-{client,server} "${pkgdir}/usr/bin/"
# Install .desktop shortcut
install -d -m755 "${pkgdir}/usr/share/applications"
install -m644 ../hydrus.desktop "${pkgdir}/usr/share/applications/${pkgbase}.desktop"
# Install license files
install -d -m755 "${pkgdir}/usr/share/licenses/${pkgbase}"
install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgbase}/"
install -m644 license.txt "${pkgdir}/usr/share/licenses/${pkgbase}/"
}
|