PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Selby Mashiki mashikiselby@gmail.com
pkgname=hyprkit-git
pkgver=r8.75f2b27
pkgrel=1
pkgdesc="A companion CLI for managing and improving your Hyprland setup"
arch=('any')
url="https://github.com/Kolgrim33/hyprkit"
license=('MIT')
keywords=('hyprland' 'wayland' 'cli' 'config' 'lint' 'doctor')
depends=('python' 'python-rich')
optdepends=('hyprland: for monitors and doctor commands')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools')
provides=('hyprkit')
conflicts=('hyprkit')
source=("$pkgname::git+https://github.com/Kolgrim33/hyprkit.git")
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$pkgname"
    python -m build --wheel --no-isolation
}

package() {
    cd "$pkgname"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}