blob: d81c403fc204caf7dacf56f081e8720be8546cf5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
# Maintainer: FabioLolix
# Maintainer: éclairevoyant
# Maintainer: alba4k <blaskoazzolaaaron@gmail.com>
# Contributor: ThatOneCalculator <kainoa at t1c dot dev>
pkgname=hyprland-git
pkgver=0.46.0.r115.ga6b26371
pkgrel=1
pkgdesc="Hyprland is an independent, highly customizable, dynamic tiling Wayland compositor that doesn't sacrifice on its looks"
arch=(x86_64 aarch64)
url="https://github.com/hyprwm/Hyprland"
license=('BSD-3-Clause' 'BSD-2-Clause')
depends=(
aquamarine-git
cairo
gcc-libs
glib2
glibc
glslang
hyprcursor-git
hyprgraphics-git
hyprland-qtutils-git
hyprlang-git
hyprutils-git
libdisplay-info
libdrm
libglvnd
libinput
libliftoff
libx11
libxcb
libxcomposite
libxcursor
libxfixes
libxkbcommon
libxrender
mesa
opengl-driver
pango
pixman
polkit
re2
seatd
systemd-libs
tomlplusplus
util-linux-libs
wayland
wayland-protocols
xcb-proto
xcb-util
xcb-util-errors
xcb-util-image
xcb-util-keysyms
xcb-util-renderutil
xcb-util-wm
xorg-xwayland
)
makedepends=(
cmake
git
glaze
hyprwayland-scanner-git
hyprland-protocols-git
#patch
#pkgconf
python # required by udis86
xorgproto
)
optdepends=(
'cmake: to build and install plugins using hyprpm'
'cpio: to build and install plugins using hyprpm'
'meson: to build and install plugins using hyprpm'
'glaze: to build and install plugins using hyprpm'
'uwsm: the recommended way to start Hyprland'
)
provides=("hyprland=${pkgver%%.r*}" "wayland-compositor")
conflicts=(hyprland)
source=(
"git+https://github.com/hyprwm/Hyprland.git"
"git+https://github.com/canihavesomecoffee/udis86.git"
)
b2sums=(
'SKIP'
'SKIP'
)
backup=("usr/share/xdg-desktop-portal/hyprland-portals.conf")
pick_mr() {
cd "$srcdir/Hyprland"
git pull origin pull/$1/head --no-edit --rebase
}
prepare() {
cd Hyprland
git submodule init
git config submodule.subprojects/udis86.url "$srcdir/udis86"
git config submodule.subprojects/tracy.update none
git -c protocol.file.allow=always submodule update
if [[ -z "$(git config --get user.name)" ]]; then
git config user.name local && git config user.email '<>' && git config commit.gpgsign false
fi
# Pick pull requests from github using `pick_mr <pull request number>`.
# e.g. `pick_mr 1000`
}
pkgver() {
cd "$srcdir/Hyprland"
git describe --long --tags --abbrev=8 --exclude='*[a-zA-Z][a-zA-Z]*' \
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/Hyprland"
cmake --no-warn-unused-cli -DCMAKE_INSTALL_PREFIX=/usr -S . -B ./build
cmake --build ./build --target all
}
package() {
cd "$srcdir/Hyprland"
DESTDIR="${pkgdir}" cmake --install build
# licenses
install -Dm0644 -t "$pkgdir/usr/share/licenses/${pkgname}" LICENSE
install -Dm0644 subprojects/udis86/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE-udis86"
}
# vi: et ts=2 sw=2
|