blob: 4a53334c6ecde7a7b07a4e0212a7e82e7f787549 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
|
# Maintainer: FabioLolix
# Maintainer: éclairevoyant
# Contributor: ThatOneCalculator <kainoa at t1c dot dev>
pkgname=hyprland-git
pkgver=0.40.0.r160.c95845b1
pkgrel=1
pkgdesc="A dynamic tiling Wayland compositor based on wlroots that doesn't sacrifice on its looks."
arch=(x86_64 aarch64)
url="https://github.com/hyprwm/Hyprland"
license=(BSD)
depends=(
cairo
gcc-libs
glib2
glibc
glslang
hyprutils
hyprcursor
hyprlang
hyprwayland-scanner
libdisplay-info
libdrm
libglvnd
libinput
libliftoff
libx11
libxcb
libxcomposite
libxfixes
libxkbcommon
libxrender
mesa
opengl-driver
pango
pixman
polkit
seatd
systemd-libs
tomlplusplus
wayland
wayland-protocols
xcb-proto
xcb-util
xcb-util-errors
xcb-util-image
xcb-util-keysyms
xcb-util-renderutil
xcb-util-wm
xorg-xinput
xorg-xwayland
)
depends+=(libdisplay-info.so)
makedepends=(
cmake
gdb
git
jq
make
meson
ninja
patch
pkgconf
xorgproto
)
optdepends=(
'cmake: to build and install plugins using hyprpm'
'cpio: to build and install plugins using hyprpm'
'meson: to build and install plugins using hyprpm'
)
provides=("hyprland=${pkgver%%.r*}")
conflicts=(hyprland)
source=(
"git+https://github.com/hyprwm/Hyprland.git"
"git+https://github.com/hyprwm/wlroots-hyprland.git"
"git+https://github.com/hyprwm/hyprland-protocols.git"
"git+https://github.com/canihavesomecoffee/udis86.git"
)
b2sums=(
'SKIP'
'SKIP'
'SKIP'
'SKIP'
)
pick_mr() {
git pull origin pull/$1/head --no-edit
}
prepare() {
cd Hyprland
git submodule init
git config submodule.subprojects/wlroots-hyprland.url "$srcdir/wlroots-hyprland"
git config submodule.subprojects/hyprland-protocols.url "$srcdir/hyprland-protocols"
git config submodule.subprojects/udis86.url "$srcdir/udis86"
git -c protocol.file.allow=always submodule update
if [[ -z "$(git config --get user.name)" ]]; then
git config user.name local && git config user.email '<>' && git config commit.gpgsign false
fi
# Pick pull requests from github using `pick_mr <pull request number>`.
git -C subprojects/wlroots-hyprland reset --hard
}
pkgver() {
git -C Hyprland describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
}
build() {
cd Hyprland
export CXXFLAGS="-w" # suppress all compiler warnings
meson setup build \
--wipe \
--prefix /usr \
--libexecdir lib \
--buildtype release \
--wrap-mode nodownload \
-D warning_level=0 \
-D b_lto=true \
-D b_pie=true \
-D default_library=shared \
-D xwayland=enabled \
-D systemd=enabled
meson compile -C build
}
package() {
cd Hyprland
meson install -C build --destdir "$pkgdir"
# FIXME: remove after xdg-desktop-portal-hyprland disowns hyprland-portals.conf
rm -rf "$pkgdir/usr/share/xdg-desktop-portal"
# license
install -Dm0644 -t "$pkgdir/usr/share/licenses/${pkgname}" LICENSE
}
# vi: et ts=2 sw=2
|