blob: c33ed0ab02d5b07a184eda14fdad5e43a7538567 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Maintainer: Integral <integral@murena.io>
_pkgname=hyprland
pkgname="${_pkgname}-nvidia-hidpi-git"
pkgver=r2722.e4e653ad
pkgrel=1
pkgdesc="A dynamic tiling Wayland compositor based on wlroots that doesn't sacrifice on its looks. (NVIDIA + HiDPI patch)"
arch=(any)
url="https://github.com/hyprwm/Hyprland"
license=('BSD')
depends=(
libxcb
xcb-proto
xcb-util
xcb-util-keysyms
libxfixes
libx11
libxcomposite
xorg-xinput
libxrender
pixman
wayland-protocols
cairo
pango
polkit
glslang
libinput
libxcb
libxkbcommon
opengl-driver
pixman
wayland
xcb-util-errors
xcb-util-renderutil
xcb-util-wm
seatd
vulkan-icd-loader
vulkan-validation-layers
xorg-xwayland-lily
libdisplay-info-git)
makedepends=(
git
cmake
ninja
gcc
gdb
meson
vulkan-headers
wayland-protocols
xorgproto)
source=("${_pkgname}::git+https://github.com/hyprwm/Hyprland.git"
"git+https://gitlab.freedesktop.org/wlroots/wlroots.git"
"git+https://github.com/hyprwm/hyprland-protocols.git"
"git+https://github.com/canihavesomecoffee/udis86.git"
"xwayland-support-HiDPI-scale.patch"
"fix-configure_notify-event.patch"
"nvidia.patch")
conflicts=("${_pkgname}")
provides=(hyprland)
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'497afb5e99cb069ed96a3c4a735ad23afe0d012ca845067aae3176e45e267ba5'
'e7cf16e39db2bde4dbc9d7ec3b4753f7643b1bf198a3179e6802a9c603437fe9'
'522b19656d7c1627ec615b6720182590570560e346c1670f9df002015707b340')
options=(!makeflags !buildflags !strip)
pkgver() {
cd "$_pkgname"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "${srcdir}/${_pkgname}"
rm -rf subprojects/wlroots subprojects/hyprland-protocols
git submodule init
git config submodule.wlroots.url "${srcdir}"/wlroots
git config submodule.subprojects/hyprland-protocols.url "${srcdir}"/hyprland-protocols
git config submodule.subprojects/udis86.url "${srcdir}"/udis86
git -c protocol.file.allow=always submodule update subprojects/wlroots
git -c protocol.file.allow=always submodule update subprojects/hyprland-protocols
git -c protocol.file.allow=always submodule update subprojects/udis86
cd subprojects/wlroots
git revert -n 18595000f3a21502fd60bf213122859cc348f9af
patch --forward --strip=1 --input="${srcdir}"/xwayland-support-HiDPI-scale.patch
patch --forward --strip=1 --input="${srcdir}"/fix-configure_notify-event.patch
patch --forward --strip=0 --input="${srcdir}"/nvidia.patch
}
build() {
cd "${srcdir}/${_pkgname}"
make fixwlr
cd "./subprojects/wlroots/" && meson build/ --prefix="${srcdir}/tmpwlr" --buildtype=release && ninja -C build/ && mkdir -p "${srcdir}/tmpwlr" && ninja -C build/ install && cd ../../
cd "./subprojects/udis86/" && cmake --no-warn-unused-cli -DCMAKE_BUILD_TYPE:STRING=Release -H./ -B./build -G Ninja && cmake --build ./build --config Release --target all -j$(shell nproc) && cd ../../
make protocols
make release
cd ./hyprctl && make all && cd ..
}
package() {
cd "${srcdir}/${_pkgname}"
mkdir -p "${pkgdir}/usr/share/wayland-sessions"
mkdir -p "${pkgdir}/usr/share/hyprland"
install -Dm755 build/Hyprland -t "${pkgdir}/usr/bin"
install -Dm755 hyprctl/hyprctl -t "${pkgdir}/usr/bin"
install -Dm644 assets/*.png -t "${pkgdir}/usr/share/hyprland"
install -Dm644 example/hyprland.desktop -t "${pkgdir}/usr/share/wayland-sessions"
install -Dm644 example/hyprland.conf -t "${pkgdir}/usr/share/hyprland"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${_pkgname}"
install -Dm755 ../tmpwlr/lib/libwlroots.so.* -t "${pkgdir}/usr/lib"
}
|