PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: alba4k <blaskoazzolaaaron@gmail.com>

_pkgname="hyprlock"
pkgname="$_pkgname-git"
pkgver=0.8.0.r1.g71d35aa
pkgrel=1
pkgdesc="Hyprland's GPU-accelerated screen locking utility"
arch=('x86_64' 'aarch64')
url="https://github.com/hyprwm/hyprlock"
license=('BSD-3-Clause')

depends=(
  'sdbus-cpp>=2.0.0'
  hyprgraphics-git
  hyprlang-git
  hyprutils-git
  libdrm
  libglvnd
  libxkbcommon
  mesa
  pam
  pango
  wayland
)
makedepends=(
  cmake
  git
  hyprwayland-scanner-git
  ninja
  wayland-protocols
)

provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")

_pkgsrc=$_pkgname
source=("$_pkgsrc::git+$url.git")
sha256sums=('SKIP')

backup=('etc/pam.d/hyprlock')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  local cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -W no-dev
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}