PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: cacarico <https://github.com/cacarico>
pkgname=hyprlua-git
pkgver=0.0.1.r4.g7d00dc0
pkgrel=1
pkgdesc="Lua 5.4 scripting support for Hyprland via hyprland.lua config"
arch=('x86_64')
url="https://github.com/cacarico/hyprlua"
license=('MIT')
depends=('hyprland' 'lua' 'pixman')
makedepends=('cmake' 'pkgconf' 'git')
options=('!debug')
provides=('hyprlua')
conflicts=('hyprlua')
source=("$pkgname::git+https://github.com/cacarico/hyprlua.git")
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    git describe --long --tags --abbrev=7 2>/dev/null \
        | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
        || printf "r%s.g%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
    cmake -B build -S "$pkgname" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr
    cmake --build build -j$(nproc)
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -Dm644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}