PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: franlol
pkgname=hyprscreen
pkgver=0.1.6
pkgrel=1
pkgdesc="A first-class screenshot and screen-recording app built for Hyprland"
arch=('x86_64')
url="https://github.com/franlol/hyprscreen"
license=('MIT')
depends=('gtk4' 'grim' 'slurp' 'wf-recorder' 'wl-clipboard' 'hyprland' 'ffmpeg'
         # Webcam bubble (default feature): v4l2src ! videoconvert ! gtk4paintablesink
         'gstreamer' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugin-gtk4')
makedepends=('cargo' 'pkg-config')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('262a4a7cf6fcf6cbeacf36dffe6ed305b0bb49ed90c1ba6d7c94a1913f88390f')

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --release --locked --offline
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}