PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Brian Crescimanno <brian.crescimanno[a]me.com>
# Inspired by: alba4k <blaskoazzolaaaron[at]gmail.com>

pkgname="hyprshutdown"
pkgver=0.1.0
pkgrel=1
pkgdesc="A graceful shutdown utility for Hyprland"
arch=('x86_64' 'aarch64')
url="https://github.com/hyprwm/hyprshutdown"
license=('BSD-3-Clause')

_pkgsrc="$pkgname-$pkgver"

depends=(
  glaze
  hyprtoolkit
  hyprutils
  pixman
  libdrm
)
makedepends=(
  cmake
  git
  ninja
)

provides=("$pkgname")

source=("$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('28b125c6d8406029b59beacb77aa080d5d8905239b1006c94c7307f1997e6819')

build() {
  local cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -W no-dev
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}