PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: alba4k <blaskoazzolaaaron[at]gmail.com>

_pkgname="hyprsunset"
pkgname="$_pkgname-git"
pkgver=0.3.3.r12.g2ccd008
pkgrel=1
pkgdesc="An application to enable a blue-light filter on Hyprland"
arch=('x86_64' 'aarch64')
url="https://github.com/hyprwm/hyprsunset"
license=('BSD-3-Clause')
depends=(
  hyprlang-git
  'hyprutils-git>=0.2.3'
  wayland
  wayland-protocols
)
makedepends=(
  'hyprland-protocols-git>=0.4.0'
  'hyprwayland-scanner-git>=0.4.0'
  cmake
  git
  ninja
)

provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")

_pkgsrc=$_pkgname
source=("$_pkgsrc::git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  local _tag=$(git tag -l --contains $(git describe --tags --abbrev=0) --sort=-v:refname | head -n1 | sed 's/^v//')
  printf "%s.r%s.g%s" "$_tag" $(git rev-list --count --cherry-pick "v${_tag}...HEAD") $(git rev-parse --short=7 HEAD)
}

build() {
  local cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -W no-dev
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
  )
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}