blob: 8d605475f3ce48270aa4f26c4ee567388a10b530 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer : Vassilis Palassopoulos <palasso [at] gmail [dot] com>
# Based on the PKGBUILD from eloaders <eloaders at linux dot pl>
pkgname=i-nex
pkgver=7.6.1
pkgrel=3
pkgdesc="System information tool like hardinfo, sysinfo"
arch=('i686' 'x86_64')
url="http://i-nex.linux.pl/"
license=('LGPL3')
depends=('gambas3-runtime'
'gambas3-gb-image'
'gambas3-gb-form'
'gambas3-gb-desktop'
'gambas3-gb-qt5'
'gambas3-gb-desktop-x11'
'python2'
'libcpuid'
'lsb-release'
'curl'
'procps-ng')
makedepends=('gambas3-devel' 'gcc' 'imagemagick')
source=("https://github.com/i-nex/I-Nex/archive/${pkgver}.tar.gz"
"Fix-error-if-proc-mtrr-doesn-t-exist.patch")
sha256sums=('81236eb729fbd29b356762c0883fe295cf1181cc7d14f00b1dfcceb517b47960'
'5c812da66cf8627e1749722d8e98f0871e6b3dbc30efbce29b785912ff39e96b')
conflicts=('i-nex-git')
backup=('etc/i-nex/Database/i2c/devices.json'
'etc/i-nex/Database/A6.json'
'etc/i-nex/Database/amd.json'
'etc/i-nex/Database/atom.json'
'etc/i-nex/Database/i3.json'
'etc/i-nex/Database/i5.json'
'etc/i-nex/Database/i7.json'
'etc/i-nex/Database/intel_Core_2_Duo.json'
'etc/i-nex/Database/intel.json'
'etc/i-nex/Database/Opteron.json'
'etc/i-nex/Database/Xeon.json')
prepare() {
cd "${srcdir}/I-Nex-${pkgver}"
patch -Np1 -i "${srcdir}/Fix-error-if-proc-mtrr-doesn-t-exist.patch"
sed -i -e 's|^STATIC.*|STATIC = false|' i-nex.mk
sed -i -e 's|^UDEV_RULES_DIR.*|UDEV_RULES_DIR = /usr/lib/udev/rules.d|' i-nex.mk
cd "I-Nex"
autoreconf -i
}
build() {
cd "${srcdir}/I-Nex-${pkgver}"
cd "I-Nex"
./configure --prefix=/usr
cd ..
MAGICK_OCL_DEVICE=OFF make -j1
}
package() {
cd "${srcdir}/I-Nex-${pkgver}"
MAGICK_OCL_DEVICE=OFF make -j1 DESTDIR="${pkgdir}/" install
}
|