PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Lukas Wölfer (domain is thasky) <aur at [domain] dot one>
pkgname=i3-insert-workspace-git
pkgver=1.3.2.r0.g6cb94c9
pkgrel=3
pkgdesc='Insert a new named workspace between two other named workspaces.'
url='https://github.com/corrodedHash/i3-insert-workspace'
source=("${pkgname}::git+https://github.com/corrodedHash/${pkgname%-git}#branch=main")
arch=('x86_64' 'i686')
license=('MIT')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")

makedepends=('cargo' 'git')
depends=()
optdepends=()

sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  # cutting off 'foo-' prefix that presents in the git tag
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$pkgname"

  RUSTUP_TOOLCHAIN=stable \
    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build () {
  cd "$srcdir/$pkgname"

  RUSTUP_TOOLCHAIN=stable \
  CARGO_TARGET_DIR=target \
    cargo build --frozen --release
}

check() {
  # cd "$srcdir/$pkgname"
  # cargo test --frozen

  echo No tests
}

package() {
  cd "$srcdir/$pkgname"
  install -Dm0755 target/release/i3-insert-workspace "${pkgdir}/usr/bin/i3-insert-workspace"
}