blob: fde340a269f7df3bf1f02cdb98c010d2a2f78071 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Jan-Erik Rediger <badboy at archlinux dot us>
# Co-Maintainer: Ingo Bürk <ingo.buerk@airblader.de>
# Contributor: Thorsten Töpper <atsutane-aur@freethoughts.de>
# Contributor: William Giokas <1007380@gmail.com>
pkgname=i3lock-git
pkgver=2.11.1.1.gd9bcb58
pkgrel=1
pkgdesc="An improved screenlocker based upon XCB and PAM"
arch=('i686' 'x86_64')
url="https://i3wm.org/i3lock/"
license=('MIT')
groups=('i3-vcs')
provides=('i3lock')
conflicts=('i3lock')
depends=('xcb-util-image' 'libev' 'cairo' 'libxkbcommon-x11')
backup=("etc/pam.d/i3lock")
options=('docs')
makedepends=('git')
source=('git://github.com/i3/i3lock#branch=master')
sha1sums=('SKIP')
_gitname='i3lock'
pkgver() {
cd "$srcdir/$_gitname"
git describe --tags | sed 's/-/./g'
}
build() {
cd "$_gitname"
# Fix ticket FS#31544, sed line taken from gentoo
sed -i -e 's:login:system-auth:' pam/i3lock
autoreconf --force --install
rm -rf build/
mkdir -p build && cd build/
../configure \
--prefix=/usr \
--sysconfdir=/etc \
--disable-sanitizers
# See https://lists.archlinux.org/pipermail/arch-dev-public/2013-April/024776.html
make CPPFLAGS+="-U_FORTIFY_SOURCE"
}
package() {
cd "$_gitname"
cd build/
make DESTDIR="$pkgdir/" install
install -Dm644 ../LICENSE \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|