blob: f4560a23c3b6906cd154bdabcfbdf957c30e5e5b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Jason Nader <jason.nader@protonmail.com>
pkgname=i3status-rust-git
pkgver=0.20.0.r1950.g1efa069
pkgrel=2
pkgdesc='Very resourcefriendly and feature-rich replacement for i3status to use with bar programs (like i3bar and swaybar), written in pure Rust'
arch=('x86_64')
url='https://github.com/greshake/i3status-rust'
license=('GPL3')
depends=('libpulse')
makedepends=('git' 'rust')
optdepends=('alsa-utils: for the volume block'
'bluez: for the bluetooth block'
'curl: for the weather block'
'fakeroot: for the pacman block to show pending updates'
'ibus: for the ibus block'
'kdeconnect: for the kdeconnect block'
'lm_sensors: for the temperature block'
'networkmanager: for the networkmanager block'
'powerline-fonts: for all themes using the powerline arrow char'
'pulseaudio: for the volume block'
'speedtest-cli: for the speedtest block'
'ttf-font-awesome-4: for the awesome icons'
'upower: for the battery block')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
install="${pkgname%-*}.install"
source=("${pkgname%-*}::git+$url")
sha1sums=('SKIP')
pkgver() {
cd "${pkgname%-*}"
echo $(grep '^version =' Cargo.toml|head -n1|cut -d\" -f2).r$(git rev-list --count HEAD).g$(git describe --always)
}
build() {
cd "${pkgname%-*}"
cargo build --release --features "pulseaudio"
}
package() {
cd "${pkgname%-*}"
install -Dm755 target/release/i3status-rs "$pkgdir/usr/bin/i3status-rs"
install -Dm644 man/i3status-rs.1 -t "$pkgdir/usr/share/man/man1"
for icon_set in files/icons/*.toml; do
install -Dm644 "$icon_set" -t "$pkgdir/usr/share/${pkgname%-*}/icons"
done
for theme in files/themes/*.toml; do
install -Dm644 "$theme" -t "$pkgdir/usr/share/${pkgname%-*}/themes"
done
for example_config in examples/*.toml; do
install -Dm644 "$example_config" -t "$pkgdir/usr/share/doc/${pkgname%-*}/examples"
done
}
|