blob: 33c5d27a797db03876327db68cfef4173031f548 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Jannik Birk <birk.jannik@gmail.com>
_target=i686-elf
pkgname=$_target-binutils
pkgver=2.29
pkgrel=1
pkgdesc='A set of programs to assemble and manipulate binary and object files for the i686-elf target'
arch=(i686 x86_64)
url='http://www.gnu.org/software/binutils/'
license=(GPL)
depends=(zlib)
source=("http://mirrors.kernel.org/gnu/binutils/binutils-$pkgver.tar.xz"
"libiberty-ignore-cflags.patch")
sha256sums=('0b871e271c4c620444f8264f72143b4d224aa305306d85dd77ab8dce785b1e85'
'8b2aea00e98f7c311b1d0fb14e4b435a03c65fde32bc992c924edb6fa7b83c9c')
_basedir=binutils-$pkgver
prepare() {
cd $_basedir
patch -p1 -i $srcdir/libiberty-ignore-cflags.patch
mkdir $srcdir/binutils-build
}
build() {
cd binutils-build
$srcdir/$_basedir/configure \
--target=$_target \
--with-sysroot=/usr/$_target \
--prefix=/usr \
--disable-nls \
--disable-werror
make
}
check() {
cd binutils-build
# do not abort on errors - manually check log files
make -k check
}
package() {
cd binutils-build
make DESTDIR="$pkgdir" install
# Remove file conflicting with host binutils and manpages for MS Windows tools
rm "$pkgdir"/usr/share/man/man1/$_target-{dlltool,nlmconv,windres,windmc}*
# Remove info documents that conflict with host version
rm -rf "$pkgdir"/usr/share/info
}
|