blob: eedd09e6ecc4b90e3248601fe16203aeae4b41ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Finlay Maroney <finman292004@protonmail.com>
_target=i686-elf
pkgname=$_target-binutils
pkgver=2.33.1
pkgrel=2
pkgdesc='A set of programs to assemble and manipulate binary and object files for the i686-elf target'
arch=(i686 x86_64)
url='http://www.gnu.org/software/binutils/'
license=(GPL)
depends=(zlib)
options=(!emptydirs !docs)
source=("http://mirrors.kernel.org/gnu/binutils/binutils-$pkgver.tar.xz"
"https://mirrors.kernel.org/gnu/binutils/binutils-$pkgver.tar.xz.sig"
"libiberty-ignore-cflags.patch")
_basedir=binutils-$pkgver
sha256sums=('ab66fc2d1c3ec0359b8e08843c9f33b63e8707efdff5e4cc5c200eae24722cbf'
'SKIP'
'8b2aea00e98f7c311b1d0fb14e4b435a03c65fde32bc992c924edb6fa7b83c9c')
validpgpkeys=("3A24BC1E8FB409FA9F14371813FCEF89DD9E3C4F")
prepare() {
cd $_basedir
patch -p1 -i $srcdir/libiberty-ignore-cflags.patch
mkdir $srcdir/binutils-build
}
build() {
cd binutils-build
$srcdir/$_basedir/configure \
--target=$_target \
--with-sysroot \
--prefix=/usr \
--bindir=/usr/bin \
--disable-nls \
--disable-werror
make
}
check() {
cd binutils-build
# do not abort on errors - manually check log files
make -k check
}
package() {
cd binutils-build
make DESTDIR="$pkgdir" install
rm -r ${pkgdir}/usr/share/{info,man}
}
|