blob: f4e746fbe2dd5b5db5ef1e3b9f63e209fb6723e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Gaël PORTAY <gael.portay@gmail.com>
pkgname=iamroot
pkgver=13
pkgrel=1
pkgdesc='Emulating the syscall chroot(2) in an unpriviliged process'
arch=('x86_64')
url="https://github.com/gportay/$pkgname"
license=('GPL')
makedepends=('lib32-glibc'
'i386-musl'
'kernel-headers-musl-i386'
'musl'
'kernel-headers-musl'
'git'
'asciidoctor')
checkdepends=('shellcheck')
options=('!strip')
source=("https://github.com/gportay/$pkgname/archive/v$pkgver.tar.gz")
sha256sums=('fc12143995b08c28a09e28a45062b1f41caf21b8bc5dbc4b552c338f6f8d74a5')
validpgpkeys=('8F3491E60E62695ED780AC672FA122CA0501CA71')
prepare() {
cd "$pkgname-$pkgver"
ln -sf support/linux.mk makefile
touch local.mk
}
build() {
cd "$pkgname-$pkgver"
make PREFIX=/usr i686/libiamroot-linux.so.2
make PREFIX=/usr i686/libiamroot-musl-i386.so.1
make PREFIX=/usr x86_64/libiamroot-linux-x86-64.so.2
make PREFIX=/usr x86_64/libiamroot-musl-x86_64.so.1
make PREFIX=/usr doc
}
check() {
cd "$pkgname-$pkgver"
make -k check
}
package() {
cd "$pkgname-$pkgver"
make PREFIX=/usr DESTDIR="$pkgdir" install-exec-i686-linux.2
make PREFIX=/usr DESTDIR="$pkgdir" install-exec-i686-musl-i386.1
make PREFIX=/usr DESTDIR="$pkgdir" install-exec-x86_64-linux-x86-64.2
make PREFIX=/usr DESTDIR="$pkgdir" install-exec-x86_64-musl-x86_64.1
make PREFIX=/usr DESTDIR="$pkgdir" libiamroot.so
make PREFIX=/usr DESTDIR="$pkgdir" install-exec
make PREFIX=/usr DESTDIR="$pkgdir" install-doc
make PREFIX=/usr DESTDIR="$pkgdir" install-bash-completion
install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|