blob: 830ea02ce32d2a93b0fee10bdfc2d056280cad85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=icecast-git
pkgver=2.4.3.r1091.g57093def
pkgrel=1
pkgdesc="A streaming media (audio/video) server"
arch=('i686' 'x86_64')
url="https://www.icecast.org/"
license=('GPL2')
depends=('glibc' 'curl' 'libxslt' 'libtheora' 'libvorbis' 'speex' 'libkate')
makedepends=('git')
provides=("icecast=$pkgver")
conflicts=('icecast')
backup=('etc/icecast.xml'
'etc/logrotate.d/icecast')
source=("git+https://gitlab.xiph.org/xiph/icecast-server.git"
"icecast.logrotate::https://gitlab.archlinux.org/archlinux/packaging/packages/icecast/-/raw/main/icecast.logrotate"
"icecast.service::https://gitlab.archlinux.org/archlinux/packaging/packages/icecast/-/raw/main/icecast.service"
"icecast.sysusers::https://gitlab.archlinux.org/archlinux/packaging/packages/icecast/-/raw/main/icecast.sysusers"
"icecast.tmpfiles::https://gitlab.archlinux.org/archlinux/packaging/packages/icecast/-/raw/main/icecast.tmpfiles")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
cd "icecast-server"
sed -i 's|url = \.\.|url = https://gitlab.xiph.org/xiph|' ".gitmodules"
git submodule sync
git submodule update --init --recursive
}
pkgver() {
cd "icecast-server"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "icecast-server"
./autogen.sh
./configure \
--prefix="/usr" \
--sysconfdir="/etc" \
--localstatedir="/var"
make
}
package() {
cd "icecast-server"
make DESTDIR="$pkgdir" install
install -Dm644 "$srcdir/icecast.logrotate" "$pkgdir/etc/logrotate.d/icecast"
install -Dm644 "$srcdir/icecast.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "$srcdir/icecast.sysusers" "$pkgdir/usr/lib/sysusers.d/icecast.conf"
install -Dm644 "$srcdir/icecast.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/icecast.conf"
}
|