summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1bfdbecea12dc29fb67ef02da847fb99afd87260 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=icu-git
pkgver=64.2.rc.r29.gbe25c277fd
pkgrel=1
pkgdesc="International Components for Unicode library"
arch=('i686' 'x86_64')
url="http://site.icu-project.org/"
license=('custom:icu')
depends=('glibc' 'sh')
makedepends=('git')
provides=('icu')
conflicts=('icu')
source=("git+https://github.com/unicode-org/icu.git")
sha256sums=('SKIP')


pkgver() {
  cd "icu"

  git describe --long --tags | sed 's/^release-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "icu/icu4c/source"

  export CC=gcc CXX=g++
  ./configure \
    --prefix="/usr" \
    --sbindir="/usr/bin" \
    --sysconfdir="/etc"
  make
}

check() {
  cd "icu/icu4c/source"

  make check
}

package() {
  cd "icu/icu4c/source"

  make DESTDIR="$pkgdir" install
  install -Dm644 "$srcdir/icu/icu4c/LICENSE" "$pkgdir/usr/share/licenses/icu/LICENSE"
}