blob: f1a5ecc113dd77c0f6bcedc90e0f8130912b8718 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
#
# Maintainer: Mark Barbone <mark.l.barbone at gmail>
#
pkgname=idris2
pkgver=0.2.0
pkgrel=1
pkgdesc="Funtional Programming Lanugage with Dependent Types"
url="https://www.idris-lang.org/"
license=('custom')
arch=('x86_64')
depends=('chez-scheme')
makedepends=('git')
source=('https://www.idris-lang.org/idris2-src/idris2-latest.tgz')
sha256sums=('03869e02cf983947c30fe66660b305114e2d21c96d3dab17efc0c7923d940db6')
_srcname="Idris2-$pkgver"
build() {
cd "$srcdir/$_srcname"
unset MAKEFLAGS # Parallel builds cause problems
export SCHEME=scheme
mkdir -p "$srcdir/bootstrap"
PREFIX="$srcdir/bootstrap" make bootstrap
PREFIX="$srcdir/bootstrap" make install
make clean
PATH="$srcdir/bootstrap/bin:$PATH" \
LD_LIBRARY_PATH="$srcdir/bootstrap/lib:$LD_LIBRARY_PATH" \
PREFIX=/usr/lib \
make
}
package() {
cd "$srcdir/$_srcname"
unset MAKEFLAGS
export SCHEME=scheme
PREFIX="$pkgdir/usr/lib" make install-idris2
PREFIX="$pkgdir/usr/lib" make install-support
for lib in prelude base network contrib ; do
cd libs/$lib
IDRIS2_PREFIX="$pkgdir/usr/lib" ../../build/exec/idris2 --install $lib.ipkg
cd ../..
done
# clean up install
mkdir -p "$pkgdir/usr/bin"
mv "$pkgdir/usr/lib/bin/idris2_app/idris2.so" "$pkgdir/usr/bin/idris2"
rm -r "$pkgdir/usr/lib/bin"
mv "$pkgdir"/usr/lib/{lib/,}libidris2_support.so
rmdir "$pkgdir"/usr/lib/lib
# Fix permissions
find "$pkgdir" -type d -exec chmod 755 {} \;
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|