PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: oom <master@spicebrains.com>
pkgname=ie-r
pkgver=0.1.1
pkgrel=1
pkgdesc="Instant Eyedropper Reborn — pixel-perfect color picker"
arch=('x86_64')
url="https://github.com/miaupaw/ie-r"
license=('custom')
depends=(
    'wayland'
    'pipewire'
    'libxkbcommon'
    'dbus'
    'fontconfig'
    'libx11'
    'libxcursor'
    'libxrandr'
    'libxi'
)
makedepends=(
    'rust'
    'cargo'
    'clang'
    'pkg-config'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('37bbac810bc7c1b7a8750336bc1236371493201a829c5ea25e21bb81a5de0cb2')

build() {
    cd "$pkgname-$pkgver"
    export LIBCLANG_PATH="/usr/lib"
    cargo build --release --locked
}

package() {
    cd "$pkgname-$pkgver"

    # Binary
    install -Dm755 "target/release/ie-r" "$pkgdir/usr/bin/ie-r"

    # Desktop entry (X-KDE-DBUS-Restricted-Interfaces for KWin ScreenShot2 authorization)
    install -Dm644 "assets/ie-r.desktop" "$pkgdir/usr/share/applications/ie-r.desktop"
    sed -i 's|Exec=ie-r|Exec=/usr/bin/ie-r|' "$pkgdir/usr/share/applications/ie-r.desktop"

    # Icon
    install -Dm644 "assets/ie-r.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/ie-r.svg"

    # License
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}