1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
# NOTE 1:
# DPS (Display PostScript) feature is obsolete and thus not enabled.
# For more information about DPS being obsolete please visit:
# https://www.x.org/releases/X11R7.7/doc/xorg-docs/graphics/dps.html
# NOTE 2:
# Linking to ghostscript libs (gslib) is disabled due to security
# issues. ImageMagick will call 'gs' executable directly instead.
# See: https://bugs.archlinux.org/task/62171
# NOTE 3:
# change font directories in build() to match yours:
# - deJaVu and GhostScript font directories are the default ones
# - Windows font directory is set according to a Wiki example
_commit='316323c99af3f296f5316ca02ad0f2033aa151b3'
_qdepth='32'
pkgbase=imagemagick-full
pkgname=('imagemagick-full' 'imagemagick-full-doc')
pkgver=7.0.10.30
pkgrel=1
arch=('x86_64')
pkgdesc="An image viewing/manipulation program (Q${_qdepth} HDRI with all features)"
url='https://www.imagemagick.org/'
license=('custom')
makedepends=(
# official repositories:
'git' 'perl' 'jbigkit' 'opencl-headers' 'glu' 'ghostpcl' 'ghostxps'
'zstd' 'chrpath' 'xorgproto'
'lcms2' 'libraqm' 'liblqr' 'fftw' 'libxml2' 'fontconfig' 'freetype2' 'libxext'
'libx11' 'bzip2' 'zlib' 'libltdl' 'jemalloc' 'djvulibre' 'gperftools' 'libraw'
'graphviz' 'openexr' 'libheif' 'openjpeg2' 'libjpeg-turbo' 'xz' 'glib2' 'pango'
'cairo' 'libpng' 'ghostscript' 'ming' 'librsvg' 'libtiff' 'libwebp' 'libwmf'
'ocl-icd' 'gsfonts' 'ttf-dejavu' 'perl'
# AUR:
'pstoedit-nomagick' 'autotrace-nomagick' 'flif' 'libfpx' 'libumem-git'
'brunsli'
)
source=("git+https://github.com/ImageMagick/ImageMagick.git#commit=${_commit}"
'arch-fonts.diff')
sha256sums=('SKIP'
'a85b744c61b1b563743ecb7c7adad999d7ed9a8af816650e3ab9321b2b102e73')
prepare() {
mkdir -p ImageMagick/docpkg/usr/share
# fix up typemaps to match Arch Linux packages, where possible
patch -d ImageMagick -Np1 -i "${srcdir}/arch-fonts.diff"
# fix for 'sh: gitversion.sh: command not found' during autoreconf
sed -i 's|(gitversion|(./gitversion|' ImageMagick/configure.ac
autoreconf -fis ImageMagick
}
build() {
cd ImageMagick
export CFLAGS+=' -I/usr/include/FLIF'
./configure \
--prefix='/usr' \
--sysconfdir='/etc' \
--enable-openmp \
--enable-opencl \
--disable-delegate-build \
--enable-cipher \
--enable-hdri \
--enable-docs \
--with-threads \
--with-modules \
--with-quantum-depth="${_qdepth}" \
--with-magick-plus-plus \
--with-perl \
--with-perl-options='INSTALLDIRS=vendor' \
--with-jemalloc \
--with-tcmalloc \
--with-umem \
--with-bzlib \
--with-x \
--with-zlib \
--with-zstd \
--with-autotrace \
--without-dps \
--with-fftw \
--with-flif \
--with-fpx \
--with-djvu \
--with-fontconfig \
--with-freetype \
--with-raqm \
--without-gslib \
--with-gvc \
--with-heic \
--with-jbig \
--with-jpeg \
--with-jxl \
--with-lcms \
--with-openjp2 \
--with-lqr \
--with-lzma \
--with-openexr \
--with-pango \
--with-png \
--with-raw \
--with-rsvg \
--with-tiff \
--with-webp \
--with-wmf \
--with-xml \
--with-dejavu-font-dir='/usr/share/fonts/TTF' \
--with-gs-font-dir='/usr/share/fonts/gsfonts' \
--with-urw-base35-font-dir='/usr/share/fonts/gsfonts' \
--with-windows-font-dir='/usr/share/fonts/WindowsFonts' \
--with-apple-font-dir='/usr/share/fonts/TTF' \
--with-fontpath='/usr/share/fonts/Type1' \
PSDelegate='/usr/bin/gs' \
XPSDelegate='/usr/bin/gxps' \
PCLDelegate='/usr/bin/gpcl6'
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() (
ulimit -n 4096
sed -e '/validate-formats/d' -i ImageMagick/Makefile
make -C ImageMagick check
)
package_imagemagick-full() {
local _majorver="${pkgver%%.*}"
local _etcdir="ImageMagick-${_majorver}"
depends=(
# official repositories:
'lcms2' 'libraqm' 'liblqr' 'fftw' 'libxml2' 'fontconfig' 'freetype2' 'libxext'
'libx11' 'bzip2' 'zlib' 'libltdl' 'jemalloc' 'gperftools' 'djvulibre' 'libraw'
'graphviz' 'openexr' 'libheif' 'openjpeg2' 'libjpeg-turbo' 'xz' 'glib2' 'pango'
'cairo' 'libpng' 'ghostscript' 'ming' 'librsvg' 'libtiff' 'libwebp' 'libwmf'
'ocl-icd' 'gsfonts' 'ttf-dejavu' 'perl'
# AUR:
'pstoedit-nomagick' 'autotrace-nomagick' 'flif' 'libfpx' 'libumem-git'
'brunsli'
)
optdepends=(
# AUR:
'imagemagick-full-doc: manual and API docs'
)
backup=(etc/"$_etcdir"/{colors,delegates,log,mime,policy,quantization-table,thresholds,type,type-{dejavu,ghostscript}}.xml)
options=('!emptydirs' 'libtool')
provides=("imagemagick=${pkgver}" "libmagick=${pkgver}" "libmagick-full=${pkgver}")
conflicts=('imagemagick' 'libmagick')
replaces=('libmagick-full')
make -C ImageMagick DESTDIR="$pkgdir" install
find "${pkgdir}/usr/lib/perl5" -name '*.so' -exec chrpath -d {} +
rm "$pkgdir"/usr/lib/*.la
# split docs
mv "${pkgdir}/usr/share/doc" ImageMagick/docpkg/usr/share/
# harden security policy: https://bugs.archlinux.org/task/62785
sed -e '/<\/policymap>/i \ \ <policy domain="delegate" rights="none" pattern="gs" \/>' -i "${pkgdir}/etc/ImageMagick-7/policy.xml"
install -D -m644 ImageMagick/{LICENSE,NOTICE} -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
package_imagemagick-full-doc() {
pkgdesc+=' (manual and API docs)'
arch=('any')
provides=("imagemagick-doc=${pkgver}")
conflicts=('imagemagick-doc')
cp -a ImageMagick/docpkg/* "$pkgdir"
install -D -m644 ImageMagick/{LICENSE,NOTICE} -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|