blob: 41c4f9ce90ecca0a75a7329f4ff3960272b16919 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
# Maintainer: Daniel Bermond < yahoo-com: danielbermond >
# ImageMagick compiled with all features and delegate libraries.
# Using quantum depth 32 (Q32) and HDRI.
# NOTE: DPS (Display PostScript) feature is obsolete and thus not enabled.
# For more information about DPS being obsolete please visit:
# http://www.x.org/releases/X11R7.7/doc/xorg-docs/graphics/dps.html
# NOTE:
# Change font directories bellow to match yours.
# DeJaVu and GhostScript font directories provided bellow are the default ones.
# Windows font directory provided bellow is set according to the example in Arch Linux Wiki.
_dejavu_font_dir="/usr/share/fonts/TTF"
_gs_font_dir="/usr/share/fonts/Type1"
_windows_font_dir="/usr/share/fonts/WindowsFonts"
pkgname=imagemagick-full-git
pkgver=7.0.2.3.r11035.g32b5039
pkgrel=2
pkgdesc="An image viewing/manipulation program (Q32 HDRI with all libs and features, Git version)"
arch=('i686' 'x86_64')
url="http://www.imagemagick.org/"
license=('custom')
depends=('jemalloc' 'bzip2' 'libx11' 'libxext' 'libxt' 'libsm' 'zlib' 'autotrace-nomagick' 'fftw' 'flif-git'
'libfpx' 'djvulibre' 'ttf-dejavu' 'fontconfig' 'freetype2' 'libraqm' 'ghostscript' 'gsfonts'
'graphviz' 'jbigkit' 'libjpeg-turbo' 'lcms' 'lcms2' 'openjpeg2' 'liblqr' 'xz' 'openexr' 'pango'
'libpng' 'librsvg' 'libtiff' 'libwebp' 'libwmf' 'libxml2' 'libmpeg2' 'opencl-headers' 'ocl-icd')
provides=("imagemagick" "imagemagick-full" "imagemagick-git" "imagemagick-fftw"
"libMagickCore-${pkgver%%.*}.Q32HDRI.so"
"libMagickWand-${pkgver%%.*}.Q32HDRI.so"
"libMagick++-${pkgver%%.*}.Q32HDRI.so")
conflicts=('imagemagick' 'imagemagick-full' 'imagemagick-git' 'imagemagick-fftw' 'imagemagick-no-hdri')
backup=("etc/ImageMagick-${pkgver%%.*}/coder.xml"
"etc/ImageMagick-${pkgver%%.*}/colors.xml"
"etc/ImageMagick-${pkgver%%.*}/delegates.xml"
"etc/ImageMagick-${pkgver%%.*}/log.xml"
"etc/ImageMagick-${pkgver%%.*}/magic.xml"
"etc/ImageMagick-${pkgver%%.*}/mime.xml"
"etc/ImageMagick-${pkgver%%.*}/policy.xml"
"etc/ImageMagick-${pkgver%%.*}/quantization-table.xml"
"etc/ImageMagick-${pkgver%%.*}/thresholds.xml"
"etc/ImageMagick-${pkgver%%.*}/type.xml"
"etc/ImageMagick-${pkgver%%.*}/type-dejavu.xml"
"etc/ImageMagick-${pkgver%%.*}/type-ghostscript.xml"
"etc/ImageMagick-${pkgver%%.*}/type-windows.xml")
options=('!docs' 'libtool' '!emptydirs')
source=("$pkgname"::'git+http://git.imagemagick.org/repos/ImageMagick.git')
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname}"
# Git, no tags available
local _version="$(grep "PACKAGE_VERSION=" ./version.sh | sed 's/[^0-9\.]*//g')"
local _release="$(grep "PACKAGE_RELEASE=" ./version.sh | sed 's/[^0-9]*//g')"
local _revision="$(printf "r%s.g%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)")"
printf "%s.%s.%s" "$_version" "$_release" "$_revision"
}
build() {
cd "${srcdir}/${pkgname}"
CPPFLAGS="-I/usr/include/FLIF" \
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-openmp \
--enable-opencl \
--enable-largefile \
--enable-static=no \
--enable-shared=yes \
--enable-fast-install=yes \
--disable-delegate-build \
--enable-cipher \
--enable-hdri \
--enable-hugepages \
--enable-docs \
--with-threads \
--with-modules \
--with-quantum-depth=32 \
--with-magick-plus-plus \
--with-perl \
--with-perl-options="INSTALLDIRS=vendor" \
--with-jemalloc \
--with-umem \
--with-bzlib \
--with-x \
--with-zlib \
--with-autotrace \
--without-dps \
--with-fftw \
--with-flif \
--with-fpx \
--with-djvu \
--with-fontconfig \
--with-freetype \
--with-raqm \
--with-gslib \
--with-gvc \
--with-jbig \
--with-jpeg \
--with-lcms \
--with-openjp2 \
--with-lqr \
--with-lzma \
--with-openexr \
--with-pango \
--with-png \
--with-rsvg \
--with-tiff \
--with-webp \
--with-wmf \
--with-xml \
--with-dejavu-font-dir="$_dejavu_font_dir" \
--with-gs-font-dir="$_gs_font_dir" \
--with-windows-font-dir="$_windows_font_dir"
make
}
package() {
cd "${srcdir}/${pkgname}"
make -j1 DESTDIR="$pkgdir/" install
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -D -m644 NOTICE "${pkgdir}/usr/share/licenses/${pkgname}/NOTICE"
# Security fix
# https://www.imagemagick.org/discourse-server/viewtopic.php?f=4&t=29588
# https://www.imagetragick.com/
sed -i '65i\ \<policy domain="coder" rights="none" pattern="EPHEMERAL" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '66i\ \<policy domain="coder" rights="none" pattern="URL" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '67i\ \<policy domain="coder" rights="none" pattern="HTTPS" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '68i\ \<policy domain="coder" rights="none" pattern="MVG" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '69i\ \<policy domain="coder" rights="none" pattern="MSL" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '70i\ \<policy domain="coder" rights="none" pattern="TEXT" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '71i\ \<policy domain="coder" rights="none" pattern="SHOW" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '72i\ \<policy domain="coder" rights="none" pattern="WIN" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
sed -i '73i\ \<policy domain="coder" rights="none" pattern="PLT" />' "${pkgdir}/etc/ImageMagick-${pkgver%%.*}/policy.xml"
}
|