1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_pkgname=ImHex
pkgname=${_pkgname,,}
pkgver=1.33.2
pkgrel=1
pkgdesc='A Hex Editor for Reverse Engineers, Programmers and people that value their eye sight when working at 3 AM'
url='https://imhex.werwolv.net'
license=('GPL-2.0-or-later')
arch=('x86_64')
depends=('glfw' 'mbedtls' 'curl' 'dbus'
'freetype2' 'file' 'hicolor-icon-theme' 'xdg-desktop-portal'
'fmt' 'yara' 'capstone')
makedepends=('git' 'cmake'
'llvm' 'librsvg' 'nlohmann-json'
'python' 'cli11' 'dotnet-runtime')
optdepends=('dotnet-runtime: support for .NET scripts')
provides=('imhex-patterns')
conflicts=('imhex-patterns-git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/WerWolv/ImHex/releases/download/v$pkgver/Full.Sources.tar.gz"
"imhex-patterns-$pkgver.tar.gz::https://github.com/WerWolv/ImHex-Patterns/archive/refs/tags/ImHex-v$pkgver.tar.gz"
0001-fix-main-Handle-different-LLVM-version.patch)
sha256sums=('c126ecebb639f68050a47d1f9ea0e060c6ae25bfade87237cb54f2e584cfa252'
'572cd4d2c10343ae7aadc0f3a553e96924bd6911ed690ab37b45b37f1148b7cb'
'1d5d5ae1d9d5e38e38b93ab701c28312a15468ad046914386bd257dcc3bf30fb')
b2sums=('97d8b0f5c7b9621bfa36dbd85f24040c7d8d7dffca154cd85ff128160428d8d590b42e348aa8dbd48b4a21f747d6a0d6c3e74fe9ee484a77f061d5ea28661e70'
'17eb5aaa9bec2418f3ca9fe23e9e3cb5443ce1a5624c3dbcece9bcbe2ca7a95a2498d7fd713bbed78854b136b9884d7f4cb0d8453ded262b6fb6efb377219a96'
'7a76a04e1eb9c8f9a7677978a47538119264363c163d094b3a8b36d22f3899a87bdbd376027646673c45d3cfded3b8f3cf8f505de80458acc95362c1e332f9d3')
options=(!lto !strip)
prepare() {
cd "$_pkgname"
patch -Np1 -i "$srcdir/0001-fix-main-Handle-different-LLVM-version.patch"
}
build() {
export CXXFLAGS="$CXXFLAGS -Wno-inconsistent-missing-override"
cmake -B build -S "$_pkgname" \
-Wno-dev \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_INSTALL_PREFIX=/usr \
-D CMAKE_SKIP_RPATH=ON \
-D IMHEX_OFFLINE_BUILD=ON \
-D IMHEX_IGNORE_BAD_CLONE=ON \
-D IMHEX_STRIP_RELEASE=OFF \
-D IMHEX_STRICT_WARNINGS=OFF \
-D IMHEX_BUNDLE_DOTNET=OFF \
-D USE_SYSTEM_LLVM=ON \
-D USE_SYSTEM_YARA=ON \
-D USE_SYSTEM_FMT=ON \
-D USE_SYSTEM_NLOHMANN_JSON=ON \
-D USE_SYSTEM_CAPSTONE=ON \
-D USE_SYSTEM_CLI11=ON \
-D IMHEX_VERSION="$pkgver"
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
# Patterns
install -dm0755 "$pkgdir/usr/share/imhex"
cp -r -t "$pkgdir/usr/share/imhex" \
"$srcdir/ImHex-Patterns-ImHex-v$pkgver"/{constants,encodings,includes,magic,nodes,patterns,plugins,scripts,tests,themes,tips,yara}
# Desktop file(s)
install -Dm0644 "$_pkgname/resources/icon.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/imhex.svg"
for size in 32 48 64 128 256; do
install -dm0755 "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps"
rsvg-convert -a -f png -w $size -o "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/imhex.png" \
"$_pkgname/resources/icon.svg"
done
# Documentation
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
"$_pkgname/README.md"
}
|