blob: 70ae880f038c22fa2fdf2b4b193f499282db8489 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_pkgname=ImHex
pkgname=${_pkgname,,}
pkgver=1.23.0
pkgrel=1
pkgdesc='A Hex Editor for Reverse Engineers, Programmers and people that value their eye sight when working at 3 AM'
url='https://imhex.werwolv.net'
license=('GPL2')
arch=('x86_64')
depends=('glfw' 'mbedtls' 'libssh2' 'curl' 'dbus'
'freetype2' 'file' 'hicolor-icon-theme' 'xdg-desktop-portal'
'fmt' 'yara')
makedepends=('git' 'cmake' 'llvm' 'nlohmann-json' 'librsvg' 'python')
optdepends=(
'imhex-patterns-git: ImHex base patterns'
)
source=("$pkgname::git+https://github.com/WerWolv/ImHex.git#tag=v$pkgver"
"nativefiledialog::git+https://github.com/btzy/nativefiledialog-extended.git"
"xdgpp::git+https://git.sr.ht/~danyspin97/xdgpp"
"libromfs::git+https://github.com/WerWolv/libromfs"
"capstone::git+https://github.com/capstone-engine/capstone#branch=next"
"pattern_language::git+https://github.com/WerWolv/PatternLanguage#tag=ImHex-v$pkgver"
0001-makepkg-Fix-compiler-check.patch
0002-fix-Deduplicate-resources-directories.patch
pl-0001-Use-C-23-standard.patch)
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'467afb63c5ef8f8c62f530df241bcb968d127973e3607bc6f97edc69df0146c4'
'2ea54ee1c52b6f4b633dc5a09f6e9e4581a737cd51fb9394e688b6dd28363043'
'c6c315b456d9e3b22f9951ddbec42a148fa7d2b754f0a4858fd7cd19a2ea724e')
b2sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'b306373f21f9e85efcbe500526de10760ddd321ff464fe35667ceb5a51ab3ac26a37804462d87eb2261d9e645456f2e414da82e62e866d8d20dee25d02ea2d6c'
'cfedf32505130f2b86bd666c11cc56095bcf2fde5f8a49112c5a266bb4b2633c50b91898c36b90f03e80d8df1ab93edb4b817473769732136ee235843f330ab7'
'7c4251311609475f591ff2263db9d87d065095e0d8afea59f6c1e236535fd730c410b8513424e2d2ffac6a4c37ea27d82681cee5720687ff5148e03151ada7f6')
options=(!lto !strip)
prepare() {
cd "$pkgname"
git submodule init
for name in nativefiledialog xdgpp libromfs capstone pattern_language; do
git config submodule.lib/external/$name.url "$srcdir/$name"
done
for name in fmt curl yara/yara; do
git config --remove-section submodule.lib/external/$name
done
git submodule update
git apply \
"$srcdir/0001-makepkg-Fix-compiler-check.patch" \
"$srcdir/0002-fix-Deduplicate-resources-directories.patch"
git -C lib/external/pattern_language apply \
"$srcdir/pl-0001-Use-C-23-standard.patch"
}
build() {
export CXXFLAGS="$CXXFLAGS -Wno-inconsistent-missing-override"
cmake -B build -S "$pkgname" \
-Wno-dev \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_INSTALL_PREFIX=/usr \
-D CMAKE_SKIP_RPATH=ON \
-D IMHEX_OFFLINE_BUILD=ON \
-D IMHEX_IGNORE_BAD_CLONE=ON \
-D IMHEX_STRIP_RELEASE=OFF \
-D USE_SYSTEM_LLVM=ON \
-D USE_SYSTEM_YARA=ON \
-D USE_SYSTEM_FMT=ON \
-D USE_SYSTEM_CURL=ON \
-D USE_SYSTEM_NLOHMANN_JSON=ON \
-D USE_SYSTEM_CAPSTONE=OFF \
-D LIBPL_ENABLE_CLI=OFF \
-D IMHEX_VERSION="$pkgver"
make -C build
}
package() {
# Executable
install -Dm0755 build/imhex "$pkgdir/usr/bin/imhex"
# Shared lib and plugins
install -Dm0755 -t "$pkgdir/usr/lib" build/lib/libimhex/libimhex.so
for plugin in builtin; do
install -Dm0755 -t "$pkgdir/usr/lib/imhex/plugins" "build/plugins/$plugin.hexplug"
done
install -dm0755 "$pkgdir/usr/share/imhex"
# Desktop file(s)
install -Dm0644 -t "$pkgdir/usr/share/applications" "$pkgname/dist/imhex.desktop"
install -Dm0644 "$pkgname/resources/icon.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/imhex.svg"
for size in 32 48 64 128 256; do
install -dm0755 "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps"
rsvg-convert -a -f png -w $size -o "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/imhex.png" \
"$pkgname/resources/icon.svg"
done
# License
install -Dm0644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Documentation
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
"$pkgname/README.md"
}
|