blob: b7ba3e71482c1052b31f624b9817319e26f349ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_pkgname=ImHex
pkgname=${_pkgname,,}
pkgver=1.16.2
pkgrel=2
pkgdesc='A Hex Editor for Reverse Engineers, Programmers and people that value their eye sight when working at 3 AM'
url='https://github.com/WerWolv/ImHex'
license=('GPL2')
arch=('x86_64')
depends=('glfw' 'mbedtls' 'libssh2'
'python' 'freetype2' 'file' 'gtk3' 'hicolor-icon-theme' 'openssl'
'yara' 'fmt')
makedepends=('git' 'cmake' 'glm' 'llvm' 'nlohmann-json' 'librsvg')
optdepends=('imhex-patterns-git: ImHex base patterns')
source=("$pkgname::git+https://github.com/WerWolv/ImHex.git#tag=v$pkgver"
"nativefiledialog::git+https://github.com/btzy/nativefiledialog-extended.git"
"xdgpp::git+https://git.sr.ht/~danyspin97/xdgpp"
"libromfs::git+https://github.com/WerWolv/libromfs"
"capstone::git+https://github.com/capstone-engine/capstone#branch=next"
0001-makepkg-Remove-external-stuff.patch
0002-archlinux-compat-Remove-unused-mbedTLS-code-from-lib.patch
libromfs-0001-Fix-code-generation-for-clang.patch
imhex.desktop)
cksums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'948907946'
'345460920'
'2244423799'
'4178124713')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'9135ba8227955249554983f680f0bbf3b5a615182f8913af1c5b0f8890a6c9dd'
'daf80fbf00f91a2dafa972c644fc5ab7fc43438e1a3d86515f7b1fa0e2ff1d13'
'5df68c1ee84ef55b07860b3b37120a21f488bbf9bff9466eb45fe81e537cd611'
'72525512a241589cecd6141f32ad36cbe1b5b6f2629dd8ead0e37812321bdde6')
b2sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'fe7d4248ab3cb04d7b78bd9b179a1fb06239c093c9960de30573e56bdddc0da993481e51fac5fad629510d0d75cac0b367ef1c8d23d58406fc5a1c4400920271'
'f694d8af5d577a5d3566efa70b391518d858ecb1743450e4c75a509ba9a5ee13a0de4b4bff260b569202d77a49d35bba4f04a25b105616b591775d93f29d6b4e'
'faa552370acc478ab155125fc029049edab8d105496201ec3763dfa5af3dc71ab334bd53545231e172643d51a4470db1a3d3573de007590bd88efe5ebef2fb44'
'7b2d029de385fdc2536f57a4364add9752b9a5dc31df501e07bff1fd69fdd1de2afa19a5ac5a4c87fbf21c5d87cc96d3fe30d58825c050f5a7d25f6d85d08efc')
prepare() {
cd "$pkgname"
git submodule init
for name in nativefiledialog xdgpp libromfs capstone; do
git config submodule.lib/external/$name.url "$srcdir/$name"
done
for name in yara/yara fmt curl; do
git config --remove-section submodule.lib/external/$name
done
git submodule update
git apply \
"$srcdir/0001-makepkg-Remove-external-stuff.patch" \
"$srcdir/0002-archlinux-compat-Remove-unused-mbedTLS-code-from-lib.patch"
git -C lib/external/libromfs apply \
"$srcdir/libromfs-0001-Fix-code-generation-for-clang.patch" || \
git -C lib/external/libromfs apply -R --check \
"$srcdir/libromfs-0001-Fix-code-generation-for-clang.patch"
}
build() {
# We force GCC for now as libromfs build with clang is broken.
cmake -B build -S "$pkgname" \
-Wno-dev \
-D CMAKE_BUILD_TYPE=RelWithDebInfo \
-D CMAKE_INSTALL_PREFIX=/usr \
-D CMAKE_SKIP_RPATH=ON \
-D USE_SYSTEM_LLVM=ON \
-D USE_SYSTEM_YARA=ON \
-D USE_SYSTEM_FMT=ON \
-D USE_SYSTEM_CURL=ON \
-D USE_SYSTEM_NLOHMANN_JSON=ON \
-D USE_SYSTEM_CAPSTONE=OFF \
-D PROJECT_VERSION="$pkgver"
cmake --build build
}
package() {
# Executable
install -Dm0755 build/imhex "$pkgdir/usr/bin/imhex"
# Shared lib and plugins
install -Dm0755 -t "$pkgdir/usr/lib" build/lib/libimhex/libimhex.so
for plugin in builtin; do
install -Dm0755 -t "$pkgdir/usr/share/imhex/plugins" "build/plugins/$plugin/$plugin.hexplug"
done
# Desktop file(s)
install -Dm0644 -t "$pkgdir/usr/share/applications" imhex.desktop
install -Dm0644 "$pkgname/resources/icon.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/imhex.svg"
for size in 32 48 64 128 256; do
install -dm0755 "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps"
rsvg-convert -a -f png -w $size -o "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/imhex.png" \
"$pkgname/resources/icon.svg"
done
# License
install -Dm0644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Documentation
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
"$pkgname/README.md"
}
|