blob: dd566d28bf5a5c084c18d419c67fad28d3ff3f6d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_pkgname=ImHex
pkgname=${_pkgname,,}
pkgver=1.32.2
pkgrel=1
pkgdesc='A Hex Editor for Reverse Engineers, Programmers and people that value their eye sight when working at 3 AM'
url='https://imhex.werwolv.net'
license=('GPL2')
arch=('x86_64')
depends=('glfw' 'mbedtls' 'curl' 'dbus'
'freetype2' 'file' 'hicolor-icon-theme' 'xdg-desktop-portal'
'fmt' 'yara' 'capstone')
makedepends=('git' 'cmake'
'llvm' 'librsvg' 'nlohmann-json'
'python' 'cli11' 'dotnet-runtime')
optdepends=('dotnet-runtime: support for .NET scripts')
provides=('imhex-patterns')
conflicts=('imhex-patterns-git')
source=("$pkgname::git+https://github.com/WerWolv/ImHex.git#tag=v$pkgver"
"nativefiledialog::git+https://github.com/btzy/nativefiledialog-extended.git#commit=5786fabceeaee4d892f3c7a16b243796244cdddc"
"xdgpp::git+https://git.sr.ht/~danyspin97/xdgpp#commit=f01f810714443d0f10c333d4d1d9c0383be41375"
# "capstone::git+https://github.com/capstone-engine/capstone#commit=097c04d9413c59a58b00d4d1c8d5dc0ac158ffaa"
"libromfs::git+https://github.com/WerWolv/libromfs#commit=0a72f7bb33d87c4fb2709b6b94bf83518ab0022d"
"libwolv::git+https://github.com/WerWolv/libwolv#commit=d25459dfa8e706af938427e979e454a8326c5984"
"pattern_language::git+https://github.com/WerWolv/PatternLanguage#tag=ImHex-v$pkgver"
"imhex-patterns::git+https://github.com/WerWolv/ImHex-Patterns#tag=ImHex-v$pkgver"
0001-fix-cmake-Fix-when-multiple-.NET-packages-are-instal.patch
0002-fix-main-Handle-different-LLVM-version.patch)
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'3b27f99abc4040630f53cb098b67d4a8086d87c9c2c6e0a6a29afd83dcd6ec3a'
'6cd6297b2269a7299f81781e9f4bcaa4b78bc69d757d2eafab10433daee6ed48')
b2sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'4c1c0451e3c4033ed331f6339342926f1ee25b6097cc9bf540f6944f089a3db2eaa42237a673522dbcfe37540b9be9563a12b5aa146d5c5e873cce36ca637b99'
'0e6fdf7cb14df8c2983822c5bc52c080d68fbc57d995cc9e24c6a84589e2dd904e48e4657a27155dcab9048a720f5d60e8fc2d70ab5d8d42b3186703a878a960')
options=(!lto !strip)
prepare() {
cd "$pkgname"
git submodule init
for name in nativefiledialog xdgpp; do
git config submodule.lib/third_party/$name.url "$srcdir/$name"
done
for name in libromfs libwolv pattern_language; do
git config submodule.lib/external/$name.url "$srcdir/$name"
done
for name in capstone fmt yara/yara; do
git config --remove submodule.lib/third_party/$name
done
git -c protocol.file.allow=always submodule update
for name in libwolv; do
git -C lib/external/pattern_language \
config submodule.external/$name.url "$srcdir/$name"
done
git -C lib/external/pattern_language -c protocol.file.allow=always \
submodule update
git apply \
"$srcdir/0001-fix-cmake-Fix-when-multiple-.NET-packages-are-instal.patch" \
"$srcdir/0002-fix-main-Handle-different-LLVM-version.patch"
}
build() {
export CXXFLAGS="$CXXFLAGS -Wno-inconsistent-missing-override"
cmake -B build -S "$pkgname" \
-Wno-dev \
-D CMAKE_BUILD_TYPE=Release \
-D CMAKE_INSTALL_PREFIX=/usr \
-D CMAKE_SKIP_RPATH=ON \
-D IMHEX_OFFLINE_BUILD=ON \
-D IMHEX_IGNORE_BAD_CLONE=ON \
-D IMHEX_STRIP_RELEASE=OFF \
-D IMHEX_STRICT_WARNINGS=OFF \
-D IMHEX_BUNDLE_DOTNET=OFF \
-D USE_SYSTEM_LLVM=ON \
-D USE_SYSTEM_YARA=ON \
-D USE_SYSTEM_FMT=ON \
-D USE_SYSTEM_NLOHMANN_JSON=ON \
-D USE_SYSTEM_CAPSTONE=ON \
-D USE_SYSTEM_CLI11=ON \
-D IMHEX_VERSION="$pkgver"
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
# Patterns
install -dm0755 "$pkgdir/usr/share/imhex"
cp -r -t "$pkgdir/usr/share/imhex" \
"$srcdir/imhex-patterns"/{constants,encodings,includes,magic,patterns,themes,tips}
# Desktop file(s)
install -Dm0644 "$pkgname/resources/icon.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/imhex.svg"
for size in 32 48 64 128 256; do
install -dm0755 "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps"
rsvg-convert -a -f png -w $size -o "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/imhex.png" \
"$pkgname/resources/icon.svg"
done
# Documentation
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
"$pkgname/README.md"
}
|