blob: 4126a300462f851e1633241feff68bfd4099b028 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributors: henning mueller <henning@orgizm.net>
pkgname=imvirt-git
_pkgname=${pkgname/-git}
pkgver=0.9.6+28+g1d62521
pkgrel=1
epoch=1
pkgdesc='Detect the virtualization technology of a machine, it is run in'
url='http://micky.ibh.net/~liske/imvirt.html'
arch=('i686' 'x86_64')
license=('GPL2')
depends=('perl' 'dmidecode' 'perl-module-find' 'perl-file-slurp' 'perl-data-dumper')
makedepends=('git')
provides=('imvirt')
conflicts=('imvirt')
options=('!emptydirs')
source=(${pkgname}::git+https://github.com/DE-IBH/imvirt)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
git describe --tags|sed 's|-|+|g'|sed -r 's|v?(.+)|\1|'
}
prepare() {
cd ${pkgname}
sed 's|/usr/sbin|/usr/bin|g' -i perl/lib/ImVirt/Utils/dmidecode/pipe.pm
autoreconf -fiv
}
build() {
cd ${pkgname}
./configure --prefix=/usr \
--libexecdir=/usr/lib/${_pkgname} \
--sbindir=/usr/bin
make
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|