blob: 24fd8a3ed690b4b20ae8b8ff30d9e1f7d15efbb6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# $Id$
# Contributor: Balló György <ballogyor+arch at gmail dot com>
pkgname=inboxer
pkgver=1.1.5
pkgrel=4
pkgdesc="Unofficial, free and open-source Google Inbox desktop app"
arch=(any)
url="https://denysdovhan.com/inboxer/"
license=(MIT)
depends=(electron)
makedepends=(npm)
options=(!strip)
source=($pkgname-$pkgver.tar.gz::https://github.com/denysdovhan/$pkgname/archive/v$pkgver.tar.gz
$pkgname.sh
$pkgname.desktop
remove-tracking.patch)
sha256sums=('75041e1d60823ff2b2213a0ac129f694acbd939b5b1a14e4a6bf2044cea99162'
'd53b45fba512d899c1a37e232d1d5cb4d95435a311f07187f359ed284407c6b6'
'3048bb5c4d50269d27a46db7ff550f226881bd77ac6672573a0075b3b75ce2a0'
'71d3fea8d7442ae0435ad4b999a5cd6a43d86277897f2114f8f3fd7836c3faa9')
prepare() {
cd "$pkgname-$pkgver"
# remove tracking from source
# this eliminates dependencies insight and firstrun. Insight was causing trouble in version 1.1.5
patch -Np1 -i "${srcdir}/remove-tracking.patch"
sed -i '/"postinstall"/d' package.json
}
build() {
cd "$pkgname-$pkgver"
npm install --production
}
package() {
mkdir -p "$pkgdir"/usr/{lib/$pkgname,share/pixmaps}
# Copy app to tmp folder, clean it up, and pack it with asar
cp -ar $pkgname-$pkgver "$pkgdir/tmp"
find "$pkgdir/tmp/node_modules" \
-name "package.json" \
-exec sed -e "s|$srcdir/$pkgname|/usr/lib/$pkgname|" \
-i {} \; \
-or -name ".*" -prune -exec rm -r '{}' \; \
-or -name "*.gyp" -prune -exec rm -r '{}' \; \
-or -name "*.gypi" -prune -exec rm -r '{}' \; \
-or -name "*.mk" -prune -exec rm -r '{}' \; \
-or -name "*Makefile" -prune -exec rm -r '{}' \; \
-or -name "bin" -prune -exec rm -r '{}' \; \
-or -name "deps" -prune -exec rm -r '{}' \; \
-or -name "doc" -prune -exec rm -r '{}' \; \
-or -name "example" -prune -exec rm -r '{}' \; \
-or -name "man" -prune -exec rm -r '{}' \; \
-or -name "nan" -prune -exec rm -r '{}' \; \
-or -name "obj.target" -prune -exec rm -r '{}' \; \
-or -name "script" -prune -exec rm -r '{}' \; \
-or -name "test" -prune -exec rm -r '{}' \; \
-or -name "tmp" -prune -exec rm -r '{}' \;
"$pkgname-$pkgver/node_modules/asar/bin/asar.js" pack "$pkgdir/tmp/" "$pkgdir/usr/lib/$pkgname/inboxer.asar"
rm -r "$pkgdir/tmp"
install -Dm755 "$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 "$pkgname-$pkgver/app/static/Icon.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
install -Dm644 "$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|