blob: 3eff2aeecb24563d5ab26c882572187f728dc2e6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# maintainer: libele <libele@disroot.org>
pkgname=inform-git
_gitpkg=inform6unix
pkgver=6.35.r6.0.g77c472b
pkgrel=1
pkgdesc="Interactive fiction compiler (git version)"
arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'pentium4' 'x86_64')
url="http://www.inform-fiction.org/"
license=('Artistic2.0' 'MIT')
provides=('inform')
conflicts=('inform')
groups=(inform)
source=('git+https://gitlab.com/DavidGriffith/inform6unix.git')
md5sums=('SKIP')
pkgver() {
cd "${_gitpkg}"
printf "%s" "$(git describe --long --tags | sed 's/v//; s/-/./g')"
}
prepare() {
cd "${srcdir}/${_gitpkg}"
git worktree add "${srcdir}/${_gitpkg}-dev" dev
make submodules
cd "${srcdir}/${_gitpkg}-dev"
make submodules
}
build() {
cd "${srcdir}/${_gitpkg}"
make PREFIX=/usr MAN_PREFIX=/usr/share
cd "${srcdir}/${_gitpkg}-dev"
make PREFIX=/usr MAN_PREFIX=/usr/share
}
package() {
cd "${srcdir}/${_gitpkg}"
make REAL_PREFIX=/usr PREFIX="${pkgdir}"/usr MAN_PREFIX="${pkgdir}"/usr/share install
cd "${srcdir}/${_gitpkg}-dev"
make REAL_PREFIX=/usr PREFIX="${pkgdir}"/usr MAN_PREFIX="${pkgdir}"/usr/share install-alt
cd "${pkgdir}"/usr/bin
rm pblorb scanblorb
}
|