summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 02224118b0c1d31298fb9c73f9d1bce8643e363a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Erik Zenker <erikzenker at posteo dot de>
pkgname=inotify-cpp-git
pkgver=v0.1.r0.g1505377
pkgrel=1
pkgdesc="C++ binding for the linux inotify library"
arch=('i686' 'x86_64')
url="https://github.com/erikzenker/inotify-cpp"
license=('MIT')
depends=(boost)
makedepends=('cmake')

source=("${pkgname}::git+https://github.com/erikzenker/inotify-cpp.git")
sha256sums=('SKIP')

prepare() {
  cd "${srcdir}/${pkgname}"

  mkdir -p build && cd build

  cmake .. -DCMAKE_BUILD_TYPE="Release" \
           -DCMAKE_INSTALL_PREFIX=/usr
}

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${srcdir}/${pkgname}/build"
  make
}

check() {
  cd "${srcdir}/${pkgname}/build"
  make test
}

package() {
  cd "${srcdir}/${pkgname}/build"
  make DESTDIR="$pkgdir/" install
}