PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: éclairevoyant

_pkgname=igt-gpu-tools
pkgname=intel-gpu-tools-git
pkgver=1.27.1.r34.31b6af91
pkgrel=1
pkgdesc="Tools for development and testing of the Intel DRM driver"
arch=(x86_64)
license=(MIT)
url="https://gitlab.freedesktop.org/drm/$_pkgname"
depends=(libdrm libpciaccess cairo python xorg-xrandr procps-ng kmod libxv libunwind peg systemd)
makedepends=('git' swig gtk-doc xorg-util-macros xorgproto meson)
provides=('intel-gpu-tools')
conflicts=('intel-gpu-tools')
source=("git+$url.git")
b2sums=('SKIP')

pkgver() {
	cd $_pkgname
	git describe --long | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
}

prepare() {
	mkdir -p build
}

build() {
	cd build
	meson ../$_pkgname \
		--prefix=/usr \
		--libexecdir=/usr/lib
	ninja
}

check() {
	cd build
	ninja test
}

package() {
	cd build
	DESTDIR="$pkgdir" ninja install

	install -Dm644 ../$_pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
}